Limit of a two variable function at the origin

Question

How can I show that the limit of the following function, when the variables {x, y} tend to zero, is zero? Mathematica gives the error

{x,y} is not a valid variable.

Domains are $0<x<10$ and $0<y<1$.

Limit[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]], {x, y} -> {0, 0}]

Any comment is welcome.

Answer 1

The Limit depends on how you approach {0, 0} so it is Indeterminate. However, you can imply (or specify) a direction of approach which gives 0 as the limit.

$Version

(* "12.0.0 for Mac OS X x86 (64-bit) (April 7, 2019)" *)

Looking at the real part of the function

Plot3D[Re[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]]], {x, -1, 
  1}, {y, -1, 1},
 PlotPoints -> 150,
 MaxRecursion -> 4,
 ClippingStyle -> None,
 AxesLabel -> Automatic]

The multivariate Limit is

Limit[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]], 
  {x, y} -> {0, 0}]

(* Indeterminate *)

or

Limit[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]], 
  {y, x} -> {0, 0}]

(* Indeterminate *)

A nested Limit is

Limit[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]], 
  {x -> 0, y -> 0}]

However, reversing the order of approach

Limit[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]], 
  {y -> 0, x -> 0}]

(* 0 *)

Which is the same as

Limit[
 Limit[Cosh[1/Sqrt[y]] Sinh[x/Sqrt[y]] - y Cosh[x/Sqrt[y]], x -> 0],
 y -> 0]

(* 0 *)