Friendly way to make previous large calculation results reusable in a new session

Question

Very often, I need to do same calculations under different parameters for comparing the results. Every calculation may generate a large data set; for example, the calculation result of Eigensystem is often a large list.

If we want to make a careful systematic investigation of the whole parameter space, the best way is to export calculation result into external file.

But before we make a careful systematic investigation of the whole parameter space, we usually need to look into several typical parameter cases to see whether the result is consistent with my original conjecture or not. Under these circumstances, my personal experience is that exporting and importing is not as flexible as directly leaving results in the notebook.

Then here is the issue of how to store results from large calculations compactly in the notebook and how to obtain the results without a re-calculation when I reopen the notebook to continue my previous analysis.

For example:

The following assigns an eigensystem to variable es

If I end my Mathematica session and then reopen the same notebook in a new season, but don't want to re-calculate, then I have to do an assignment like below

But in this way, the input cell is way too large! I don't know how to hide it. And this way is just too awkward!

One possible way is to seek method to pack the large output of calculation into something that Dispatch would generate like the following.

I found the dispatch object is reusable when reopen mma.

I also wish to get any advice that might be forthcoming about properly organizing calculations which give results intended for use in futher analysis?

Answer 1

LocalSymbol lets you persistently save objects to your filesystem.

LocalSymbol["x"] = (Pause[5]; 6);
Quit[]

then restart the kernel and run

LocalSymbol["x"]

The output is an immediate 6.

Answer 2

Disclaimer: If used with large expressions, wrapping it in the described way introduces some kind of overhead on saving the notebook. Also, I haven't tested this extensively, there might be other problems!

To create a "folding" functionality akin to what you get from the Dispatch box for example, we can take a look at this answer. Using the technique described there we can create a wrapper to hide the contents of any expression:

label[lbl_, v_] := Row[{Style[lbl <> ": ", "SummaryItemAnnotation"], v}];

iconize /: MakeBoxes[ifun : iconize[s1_], fmt_] := 
  BoxForm`ArrangeSummaryBox[Head@s1, ifun, 
    "", {label["LeafCount", LeafCount@s1]}, 
      {label["Content", OutputSizeLimit`Short@s1]}, fmt];

Using this we can then do something like

ls = iconize@Range[100]
ListPlot@ls[[1]]

where in the second line the data has to be unwrapped from the iconize.

Note that automatic unwrapping can be achieved by the additional definition

iconize /: (h : Except[Set])[t1___, iconize[s1_], t2___] := h[t1, s1, t2]

However, this introduces a strange behaviour when copy/paste-ing the output.

Answer 3

Use of tagging rules as mentioned by Kuba.

es = Eigensystem[RandomReal[{0, 1}, {100, 100}]];

SetOptions[EvaluationNotebook[], TaggingRules -> {"varname" -> es}]

NotebookSave[]

Quit[]

In a new session the data can be recovered like so.

es = CurrentValue[{TaggingRules, "varname"}]