Integrate gives Simplify::infd "simplified to Indeterminate" message

Question

Using version 10.1 on windows 7 Integrate gives this Simplify::infd Kernel message. What causes it, is this a bug?

ClearAll[a, b, c, x]
Integrate[1/(-Sqrt[b^2 - c^2] + b*Cosh[x] + c*Sinh[x])^(1/2), x]

I checked that the same message shows up in 10.02 and in 9.0

Rubi 4.7 on 10.1, gives an answer which is

  Int[1/(-Sqrt[b^2 - c^2] + b*Cosh[x] + c*Sinh[x])^(1/2), x]
  (*-((Sqrt[2]*ArcTanh[((b^2 - c^2)^(1/4)*Sinh[x + I*ArcTan[b, (-I)*c]])/
             (Sqrt[2]*
         Sqrt[-Sqrt[b^2 - c^2] + 
           Sqrt[b^2 - c^2]*Cosh[x + I*ArcTan[b, (-I)*c]]])])/(b^2 - 
      c^2)^(1/4))
   *)

Answer 1

The reason this is happening might be because Mathematica is internally producing AppellF1 functions. If you replace Sqrt[b^2 - c^2] with Sqrt[k] and integrate, then afterwards put back the b^2 - c^2 you get this mess ...

tmp = Integrate[1/(-Sqrt[k] + b*Cosh[x] + c*Sinh[x])^(1/2), x];
tmp //. k -> b^2 - c^2

(* Result *)
  (1/(Sqrt[1 - b^2/c^2] c))2 AppellF1[1/2, 1/2, 1/2, 3/2, (
  I (Sqrt[b^2 - c^2] - b Cosh[x] - c Sinh[x]))/(
  Sqrt[1 - b^2/c^2] c + I Sqrt[b^2 - c^2]), (
  I (-Sqrt[b^2 - c^2] + b Cosh[x] + c Sinh[x]))/(
  Sqrt[1 - b^2/c^2] c - I Sqrt[b^2 - c^2])] Sech[
  x + ArcTanh[b/c]] Sqrt[-Sqrt[b^2 - c^2] + b Cosh[x] + 
  c Sinh[x]] Sqrt[((b^2 - c^2) (1 - I Sinh[x + ArcTanh[b/c]]))/(
  b^2 - c^2 + I Sqrt[1 - b^2/c^2] c Sqrt[
  b^2 - c^2])] Sqrt[((b^2 - c^2) (1 + I Sinh[x + ArcTanh[b/c]]))/(
  b^2 - c (c + I Sqrt[1 - b^2/c^2] Sqrt[b^2 - c^2]))]

But the AppelF1 part will evaluate to complex infinity everywhere for any choice of b and c. To see why, look at the AppellF1 part of this expression and you'll see...

AppellF1[1/2, 1/2, 1/2, 3/2, (
 I (Sqrt[b^2 - c^2] - b Cosh[x] - c Sinh[x]))/(
 Sqrt[1 - b^2/c^2] c + I Sqrt[b^2 - c^2]), (
 I (-Sqrt[b^2 - c^2] + b Cosh[x] + c Sinh[x]))/(
 Sqrt[1 - b^2/c^2] c - I Sqrt[b^2 - c^2])]

...we can re-express the denominators of AppellF1's last two arguments in terms of k in Sqrt[1 - b^2/c^2] c + I Sqrt[b^2 - c^2] and Sqrt[1 - b^2/c^2] c - I Sqrt[b^2 - c^2] which gives: (Sqrt[-k] + I Sqrt[k]) and Sqrt[-k] - I Sqrt[k]. The problem is that for any choice of k=b^2-c^2, the result will be zero for at least one of the denominators, which leads to a division by zero and infinite arguments in the AppellF1 function.

I'm not sure if you can get around this with some assumptions on b and c. It looks like a bug and I don't think AppellF1 should even be generated.