0
$\begingroup$

I am trying to find the result of quite a complicated double integral. While the first part (being a Principal value integral) gave no particular problems, the second one is not providing any closed expression. Here is my code:

f[x_]:=(p^2 + k^2 - 2 p k x)/(x - (p^2 + k^2 + 1 - ((p^2 - k^2)^2)/4)/(2 p k))
Integrate[f[x], {x, -1, 1}, PrincipalValue -> True]

ConditionalExpression[1/2 k p (-8 + ((-4 + (k^2 - p^2)^2) ArcCoth[(
 8 k p)/(-4 + k^4 - 4 p^2 + p^4 - 2 k^2 (2 + p^2))])/(k p)), 
k^4 + p^4 < 
  4 + 4 p^2 + 2 k^2 (2 + p^2) && (k - p)^2 (-2 + k + p) (2 + k + p) > 
  4]

g[p_, k_] := 


1/2 k p (-8 + ((-4 + (k^2 - p^2)^2) ArcCoth[(
       8 k p)/(-4 + k^4 - 4 p^2 + p^4 - 2 k^2 (2 + p^2))])/(k p));

nferm[k_]:=1/(Exp[b Sqrt[k^2 + 1]]+1);

Integrate[(k^2 nferm[k])/(2 p k) g[p,k],{k,0,Infinity}]

When I tried to run this, 2 or three minutes of waiting and they just threw back the expression without evaluating it. Can anyone help me with this?

$\endgroup$
6
  • $\begingroup$ There are a lot of integrals that can't be expressed in "closed form" by using OTS functions. Why do you think yours isn't one of them? $\endgroup$ Apr 7, 2015 at 12:12
  • $\begingroup$ I'm not sure. It's part of a paper that I'm studying for my thesis. They solved it plotted it somehow. $\endgroup$
    – Judas503
    Apr 7, 2015 at 12:30
  • $\begingroup$ In order to plot it you just need to solve it numerically. Getting a closed form isn't necessary $\endgroup$ Apr 7, 2015 at 12:34
  • $\begingroup$ Are k, p, and b all real. Also, what version of Mathematica are you using? I obtain a different answer for Integrate[f[x], {x, -1, 1}, PrincipalValue -> True] with version 10.1. $\endgroup$
    – bbgodfrey
    Apr 8, 2015 at 22:41
  • $\begingroup$ @bbgodfrey I'm using Mathematica 9. It is quite strange because when I ran the Principal Value integral for the first time, I obtained a result in terms of Log. But later, on two or three runs, I got a different answer. $\endgroup$
    – Judas503
    Apr 10, 2015 at 12:53

1 Answer 1

2
$\begingroup$

With version 9.0.1,

f[x_] := (p^2 + k^2 - 2 p k x)/(x - (p^2 + k^2 + 1 - ((p^2 - k^2)^2)/4)/(2 p k)); 
ans9 = Integrate[f[x], {x, -1, 1}, PrincipalValue -> True]
(* ConditionalExpression[1/2 k p (-8 + ((-4 + (k^2 - p^2)^2) 
   ArcCoth[(8 k p)/(-4 + k^4 - 4 p^2 + p^4 - 2 k^2 (2 + p^2))])/(k p)), 
   k^4 + p^4 < 4 + 4 p^2 + 2 k^2 (2 + p^2) && (k - p)^2 (-2 + k + p) (2 + k + p) > 4] *)

Some insight can be gained by plotting the solution ad its region of validity as specified by ConditionalExpression,

RegionPlot[Evaluate[ans9[[2]]], {k, -5, 5}, {p, -5, 5}, FrameLabel -> {k, p}]

enter image description here

Plot3D[Evaluate[ans9[[1]]], {k, -5, 5}, {p, -5, 5}, PlotPoints -> 100,
  PlotRange -> All, Mesh -> None, AxesLabel -> {k, p, z}]

enter image description here

Thus, the solution is real and continuous over a wider range than that given by the ConditionalExpression. Nonetheless, the actual range is bounded by singularities, so it is not surprising that the second Integrate in the question does not yield an answer. Of course, even without the singularities, Integrate might fail, if no known symbolic solution exists.

Because, I presume, k and p are meant to be Reals, it is reasonable to inform Integrate of this.

ans9r = Integrate[f[x], {x, -1, 1}, PrincipalValue -> True, 
  Assumptions -> k ∈ Reals && p ∈ Reals]
(* ConditionalExpression[1/2 k p (-8 + ((-4 + (k^2 - p^2)^2) 
   ArcTanh[(8 k p)/(-4 + k^4 - 4 p^2 + p^4 - 2 k^2 (2 + p^2))])/(k p)),
   (-4 + (k - p)^2) (k + p)^2 <= 4 && (k - p)^2 (-2 + k + p) (2 + k + p) <= 4] *)

which produces a different but related solution (perhaps, a different branch).

enter image description here

enter image description here

Between them, the two solutions cover all of p - k space. Nonetheless, it is unclear whether patching the two together and then integrating would be successful, due to branchpoints at z = 1 and z = -1, where z is the argument of ArcTanh or ArcCoth in the expressions above.

Answer to question in a comment above: Although version 10.1 produces symbolic solutions that appear different from the version 9.0.1 solutions.

(* ConditionalExpression[1/4 (-(-4 + (k^2 - p^2)^2) Log[-k p] + (k^2 - p^2)^2 (Log[k p]
   - Log[4 - (-4 + (k - p)^2) (k + p)^2] + Log[4 - (k - p)^2 (-2 + k + p) (2 + k + p)])
   - 4 (4 k p + Log[k p] - Log[4 - (-4 + (k - p)^2) (k + p)^2] + 
   Log[4 - (k - p)^2 (-2 + k + p) (2 + k + p)])),
   (-4 + k^4 - 4 p^2 + p^4 - 2 k^2 (2 + p^2))/(k p) ∈ Reals] *)

and

(* ConditionalExpression[1/4 (-16 k p - (-4 + (k^2 - p^2)^2) 
   Log[4 - (-4 + (k - p)^2) (k + p)^2] + (-4 + (k^2 - p^2)^2) 
   Log[4 - (k - p)^2 (-2 + k + p) (2 + k + p)]), 
   k^4 + p^4 <= 4 + 4 p^2 + 2 k^2 (2 + p^2) && (-4 + (k - p)^2) (k + p)^2 <= 4] *)

their 3D plots are identical respectively to the fourth and second plots above, although their asserted ranges of validity differ. Even though a straightforward application of FullSimplify does not succeed in showing the respective version 9.0.1 and version 10.1 solutions to be identical, it appears that they are from identities in Wolfram MathWorld.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.