How to find a closed-form expression for this integral depending on parameter?

Question

In 14.0 under Windows 10 I try to find the improper integral $$\int\limits_{\sqrt{1-\sqrt{1-\psi }}}^{\sqrt{1+\sqrt{1-\psi }}} \frac{1}{r^2 \sqrt{-r^4+2 r^2-\psi }}\,dr$$ under the assumptions $\psi >0\land \psi <1$.

Unfortunately,

Integrate[1/r^2/Sqrt[2 r^2 - r^4 - \[Psi]], {r, Sqrt[1 - Sqrt[1 - \[Psi]]], 
Sqrt[1 + Sqrt[1 - \[Psi]]]},  Assumptions -> \[Psi] > 0 && \[Psi] < 1]

returns the input as well as

\[Psi] = 1/n; Integrate[1/r^2/Sqrt[2 r^2 - r^4 - \[Psi]], {r, Sqrt[1 - Sqrt[1 - \[Psi]]], 
Sqrt[1 + Sqrt[1 - \[Psi]]]}, Assumptions -> n \[Element] PositiveIntegers]

For many rational values of \[Psi](for example, 2/3,1/3,1/7,...) Mathematica calculates this integral. However, it is difficult to derive the general formula from those values.

The numerical value

f[\[Psi]_?NumericQ] := NIntegrate[ 1/r^2/Sqrt[2 r^2 - r^4 - \[Psi]], 
{r, Sqrt[1 - Sqrt[1 - \[Psi]]], Sqrt[1 + Sqrt[1 - \[Psi]]]}]
Plot[f[\[Psi]], {\[Psi], 0, 1}]

says nothing about the rate of the growth of f[\[Psi]] as \[Psi] tends to zero from above. Concerning \[Psi] tends to 1, the result of

\[Psi] = 0.99900000000000000000000000000; 
NIntegrate[1/r^2/Sqrt[2 r^2 - r^4 - \[Psi]], {r, Sqrt[1 - Sqrt[1 - \[Psi]]],  Sqrt[1 + Sqrt[1 - \[Psi]]]}, WorkingPrecision -> 20]

1.5722703994037859370

suggests this equals Pi/2.

I also try to find an antiderivative by

ad = Integrate[1/r^2/Sqrt[2 r^2 - r^4 - \[Psi]], r, 
Assumptions -> \[Psi] > 0 && \[Psi] < 1, GenerateConditions -> True]

(-((-2 r^2 + r^4 + \[Psi])/r) + (1/Sqrt[(1/(-1 + Sqrt[1 - \[Psi]]))]) I Sqrt[1 - r^2/( 1 + Sqrt[1 - \[Psi]])] (1 + Sqrt[1 - \[Psi]]) Sqrt[(-1 + r^2 + Sqrt[1 - \[Psi]])/(-1 + Sqrt[ 1 - \[Psi]])] (EllipticE[ I ArcSinh[r Sqrt[1/(-1 + Sqrt[1 - \[Psi]])]], ( 1 - Sqrt[1 - \[Psi]])/(1 + Sqrt[1 - \[Psi]])] - EllipticF[I ArcSinh[r Sqrt[1/(-1 + Sqrt[1 - \[Psi]])]], ( 1 - Sqrt[1 - \[Psi]])/(1 + Sqrt[1 - \[Psi]])]))/(Sqrt[ 2 r^2 - r^4 - \[Psi]] \[Psi])

Rubi produces the same result in a simpler form:

Get["Rubi`"]
adRubi = Int[1/r^2/Sqrt[2 r^2 - r^4 - \[Psi]], r]
Plot3D[Re[adRubi - ad], {r, 0, 1}, {\[Psi], 0, 1}]

Both results are doubtful in view of

u = ad /. r -> Sqrt[1 + Sqrt[1 - \[Psi]]];
l = ad /. r -> Sqrt[1 - Sqrt[1 - \[Psi]]];
FullSimplify[u - l, Assumptions -> \[Psi] > 0 && \[Psi] < 1]

Indeterminate

and

u - l /. \[Psi] -> 0.5

Indeterminate

The command

ClearAll[\[Psi]]; Limit[ad, r -> Sqrt[1 + Sqrt[1 - \[Psi]]], 
 Direction -> "FromBelow", Assumptions -> \[Psi] > 0 && \[Psi] < 1]

is running without any response for a long time.

So is it possible to find a closed-form expression for the integral under consideration with Mathematica? PS. Maple 2023 answers $$ \frac{\left(1-\sqrt{1-\psi}\right) \mathrm{EllipticE}\! \left(\sqrt{2}\, \sqrt{\frac{\sqrt{1-\psi}}{1+\sqrt{1-\psi}}}\right)}{\psi \sqrt{1+\sqrt{1-\psi}}\, \left(1-\frac{2 \sqrt{1-\psi}}{1+\sqrt{1-\psi}}\right)}$$

Answer 1

A change of variables can help:

integrand = 1/r^2/Sqrt[2  r^2 - r^4 - ψ];

i2 = 
 IntegrateChangeVariables[
   Inactive[Integrate][
     integrand, 
     {r, Sqrt[1 - Sqrt[1 - ψ]], Sqrt[1 + Sqrt[1 - ψ]]}
    ], 
   s, 
   s == r^2 - 1, 
   Assumptions -> ψ > 0 && ψ < 1
  ]

(*Inactive[Integrate][1/(
 2 (1 + s)^(3/2) Sqrt[1 - s^2 - ψ]), {s, -Sqrt[1 - ψ], Sqrt[
  1 - ψ]}]*)

i3=Integrate[i2[[1]], i2[[2]], Assumptions -> ψ > 0 && ψ < 1]
(* (1/(2 ψ))(Sqrt[1 - Sqrt[1 - ψ]]
    EllipticE[(2 (-1 - Sqrt[1 - ψ] + ψ))/ψ] + 
  Sqrt[1 + Sqrt[1 - ψ]]
    EllipticE[(2 (-1 + Sqrt[1 - ψ] + ψ))/ψ]) *)

$$ \frac{\sqrt{1-\sqrt{1-\psi }} E\left(\frac{2 \left(\psi -\sqrt{1-\psi }-1\right)}{\psi }\right)+\sqrt{\sqrt{1-\psi }+1} E\left(\frac{2 \left(\psi +\sqrt{1-\psi }-1\right)}{\psi }\right)}{2 \psi } $$

A brief numeric test seems to support this result:

Table[i3, {ψ, 0.1, 0.9, 0.1}]
(* {14.4606, 7.33593, 4.94922, 3.75053, 3.02835, 2.54501, \
2.19849, 1.93769, 1.73415} *)

Table[NIntegrate[integrand,
  {r, Sqrt[1 - Sqrt[1 - ψ]], 
   Sqrt[1 + Sqrt[1 - ψ]]}], {ψ, 0.1, 0.9, 0.1}]
(* {14.4606, 7.33593, 4.94922, 3.75053, 3.02835, 2.54501, \
2.19849, 1.93769, 1.73415} *)

Also

Limit[i3, ψ -> 1]
(* π/2 *)