Changeable header and footer banners in Slide Show style

Question

I would like to create Mathematica slide shows that contain several tailored, fixed banners as headers and footers, much as MS Powerpoint, MS Word, Apple Pages, and LaTeX documents allow one to specify headers and footers. I would like a more powerful form of Slide Show template in which I design Header1, Footer1, Header2, Footer2, etc., which might contain a corporate logo, colored background, navigation buttons (prior page, next page, etc.), section titles such as Introduction, Approach, Results, Conclusion (for an academic presentation, for instance). During composition, Header1 and Footer1 stay in effect until I deliberately select Header2 and Footer2.

I've searched through Mma SE without full success (How to make the docked cell and the navigation toolbar in the Slide Show?), and the Slide Show palette enables page numbering, dates, and such, but not (as far as I can tell) several header designs containing special figures, text, and so on that can be selected as needed, and re-used within different shows.

Answer 1

If you start with a simple CreateNotebook["SlideShow"], click Blank Slide from the Classic Slide Show palette and add some text, you get something like that:

Now you create a palette with buttons with code for your different header cells. Here we have two buttons.

CreatePalette[{Button[
   "First banner", 
   NotebookWrite[InputNotebook[], 
    Cell[
     BoxData[
      RowBox[{ToBoxes[
         Text[
          Style["My first banner", 24, Italic, FontFamily -> "Times", 
           Background -> Yellow]]]}]], "DockedCell"]]
   ],
  Button[
   "Second banner", 
   NotebookWrite[InputNotebook[], 
    Cell[
     BoxData[
      RowBox[{ToBoxes[
         Text[
          Style["My second banner", 24, Italic, FontFamily -> "Times",
            Background -> Yellow]]]}]], "DockedCell"]]
   ]
  }]

If you position your cursor just below Slide 1 of 1 and click a button on your palette, it will produce the header cell docked on slide 1. You can then repeat for each slide.

============ ANOTHER APPROACH ============

If you wish to experiment, here is a short Palette with one button. Selecting a presentation and clicking the button will create a docked cell that changes depending on the slide displayed. The presentation is one provided with Mathematica.

CreatePalette[
 Button[
  "Header Cells",
  currentDock = AbsoluteCurrentValue [InputNotebook[], DockedCells];
  SetOptions[InputNotebook[], DockedCells -> AppendTo[currentDock,
     Cell[BoxData[RowBox[{ToBoxes[Text[Style[
            Dynamic[
             contents = Switch[
               
               val = 
                Refresh[
                 CurrentValue[{"CounterValue", 
                   "SlideShowNavigationBar"}], UpdateInterval -> 1],
               1, Text[" Slide 1"],
               2, Text[" Slide 2"],
               3, 
               Row[{Import["ExampleData/spikey.tiff", 
                  ImageSize -> Small], Text[" Slide 3"]}],
               4, Text[" Slide 4"],
               5, Text[" Slide 5"],
               6, Text[" Slide 6"],
               _, Text[""]
               ]],
            24, Italic, FontFamily -> "Times", 
            Background -> Yellow]]]}]], "DockedCell", 
      Background -> LightBlue
      ]
     ]
   ]
  ]
 ]

Answer 2

A partial answer is the following:

With[{myCell = 
   Cell[BoxData[
     RowBox[{ToBoxes[
        Text[Style["My banner", 24, Italic, FontFamily -> "Times", 
          Background -> Yellow]]]}]], "DockedCell"]},
 nb = NotebookCreate[
   ScreenStyleEnvironment -> "SlideShow",
   DockedCells -> 
    Dynamic[If[
      CurrentValue[EvaluationNotebook[], ScreenStyleEnvironment] === 
       "SlideShow",
      {Inherited, myCell}, myCell]]]]

This then creates a SlideShow notebook that has my fixed banner at the top. I don't know how to create a "footer" banner, nor change one within the SlideShow notebook.

I wouldn't mind (too much) if I had to make several separate SlideShows with different headers and then concatenate them into a single SlideShow retaining the separate headers, but apparently this is not possible.

Answer 3

You can create a footer using AttachCell (new in Mathematica 12.2):

footerObj = 
 AttachCell[EvaluationNotebook[], 
  Panel[Style["Footer", 30], ImageSize -> {Full, All}, Background -> LightBlue, 
   Alignment -> Center], "Inline", 2, Bottom]

Here is how it is displayed in the "SlideShow" environment:

If you use Mathematica version lower than 12.2, try FrontEnd`AttachCell instead.

Since attached cells (as well as docked cells) support Dynamic, you can make them dependent on the slide number using CurrentValue[{"CounterValue", "SlideShowNavigationBar"}]:

footerObj = 
 AttachCell[nb, 
  Panel[Style[
    Row[{"Footer of Slide ", 
      Dynamic@CurrentValue[{"CounterValue", "SlideShowNavigationBar"}]}], 30], 
   ImageSize -> {Full, All}, Background -> LightBlue, Alignment -> Center], "Inline", 2, 
  Bottom]

Of course, you can write a function which will display a predefined expression on the current footer depending on the slide number.

You can even automatically extract and display the heading of the selected section on the slide using an approach similar to this one.

---

Since the attached cells exist only diring current session and will be lost upon saving and reopening the Notebook, it is reasonable to put the code for them into NotebookDynamicExpression.