Hypergeometric function with a matrix argument

Question

I am looking for the evaluation of a Hypergeometric function with a matrix argument as for example in Koev and Edelman or as showcased in this Wikipedia article.

From what I understand from Mathematica's documentation, it only accepts a scalar as the last argument.

Answer 1

Matrix functions in MMA

First of all MMA does in general not support matrix arguments in its standard functions. Therefore there are special functions MatrixExp and MatrixPower available. But, as will be shown in this answer, it is possible to create user defined functions via infinite series, and it turns out that MMA is surprisingly well able in dealing with these matrix functions. The idea is simple: a function with a known series expansion can be transformed into a Matrix function letting z^k -> MatrixPower[z,k].

Hypergeometric matrix function in one variable

Let us start with the well known function $2F1(a,b,c;z)$ which in MMA is Hypergeometric2F1[a,b,c,z], and define

matrix2F1[a_, b_, c_, z_] := 
 Sum[Pochhammer[a, k] Pochhammer[b, k]/
    Pochhammer[c, k] MatrixPower[z, k]/k!, {k, 0, \[Infinity]}]

Here z is a matrix.

Example 1: Pauli matrix

z = PauliMatrix[1]

$\left( \begin{array}{cc} 0 & 1 \\ 1 & 0 \\ \end{array} \right)$

matrix2F1[a,b,c,z]

$\left( \begin{array}{cc} \frac{1}{2} (\text{Hypergeometric2F1}[a,b,c,-t]+\text{Hypergeometric2F1}[a,b,c,t]) & \frac{1}{2} (-\text{Hypergeometric2F1}[a,b,c,-t]+\text{Hypergeometric2F1}[a,b,c,t]) \\ \frac{1}{2} (-\text{Hypergeometric2F1}[a,b,c,-t]+\text{Hypergeometric2F1}[a,b,c,t]) & \frac{1}{2} (\text{Hypergeometric2F1}[a,b,c,-t]+\text{Hypergeometric2F1}[a,b,c,t]) \\ \end{array} \right)$

I found it very surprising that MMA computes the series and recognizes closed expressions without problems.

Example 2: general 2x2 matrix

z = {{p, q}, {r, s}}

$\left( \begin{array}{cc} p & q \\ r & s \\ \end{array} \right)$

matrix2F1[1, 2, 2, z t] // FullSimplify;
% // MatrixForm

$\left( \begin{array}{cc} \frac{1-s t}{1-t (s+q r t)+p t (-1+s t)} & -\frac{q t}{-1+t (p+s+q r t-p s t)} \\ -\frac{r t}{-1+t (p+s+q r t-p s t)} & \frac{1-p t}{1-t (s+q r t)+p t (-1+s t)} \\ \end{array} \right)$

Hypergeometric matrix function in two variables

For two variables there is a problem to be clarified first: two matrices in general do not commute, i.e. the result of a multiplication depends on the order. Hence $f(x,y)\neq f(y,x)$, in general. A relation between $f(x,y)$ and $f(y,x)$ become a Little simpler if x.y = A y.x + B with some scalars A and B. But let's us Abandon this question for a Moment and go to the hypergeometrics.

There are 4 different generalizations of the hypergeometric function, called Appell functions (http://mathworld.wolfram.com/AppellHypergeometricFunction.html).

Let's take the first one and define

matrixAppellF1[a_, b_, b1_, c_, x_, y_] := 
 Sum[(Pochhammer[a, m + n] Pochhammer[b, m] Pochhammer[b1, n])/(
   m! n! Pochhammer[c, m + n])
    MatrixPower[x, m].MatrixPower[y, n], {m, 0, \[Infinity]}, {n, 
   0, \[Infinity]}]

Here we have taken the powers of x together to the left of the powers of y. This seems to be Kind of "natural", but there are other possibilities.

Example 3: AppelF1[a,b,b1,c,x,y]

First check result with scalars

AppellF1[1, 1, 1, 1, t , u ]

$\frac{1}{(1-t) (1-u)}$

x = PauliMatrix[1];
y = PauliMatrix[3];

matrixAppellF1[1, 1, 1, 1, t x, u y]

$\left( \begin{array}{cc} -\frac{1}{(-1+t) (1+t) (1-u)} & -\frac{t}{(-1+t) (1+t) (1+u)} \\ -\frac{t}{(-1+t) (1+t) (1-u)} & -\frac{1}{(-1+t) (1+t) (1+u)} \\ \end{array} \right)$

Summary

We have shown that MMA is very well suited to handle complicated functions with Matrix arguments.We simply have to replace in the power series Expansion of the usual function the power of the variable z^k with MatrixPower[z,k].

Surprisingly enough, MMA can do the infinite sums and provide closed expressions.

By the way: the there is no need for the user to think about eigenvalues or diagonalization.

Best regards, Wolfgang

Answer 2

You can use the new in M9 function MatrixFunction to do this. For instance:

MatrixFunction[Hypergeometric2F1[a, b, c, #]&, {{0, 1}, {1, 0}}] //TeXForm

$\left( \begin{array}{cc} \frac{\, _2F_1(a,b;c;-1)}{2}+\frac{\, _2F_1(a,b;c;1)}{2} & \frac{\, _2F_1(a,b;c;1)}{2}-\frac{\, _2F_1(a,b;c;-1)}{2} \\ \frac{\, _2F_1(a,b;c;1)}{2}-\frac{\, _2F_1(a,b;c;-1)}{2} & \frac{\, _2F_1(a,b;c;-1)}{2}+\frac{\, _2F_1(a,b;c;1)}{2} \\ \end{array} \right)$

Answer 3

To expand on my comment to the question: there is in fact an "official" recommendation for how to approach this in the documentation of DiagonalizableMatrixQ, under "Applications". It uses the idea that for a function that can be expanded in a power series, we can always convert a matrix argument into set of a scalar arguments if the matrix is diagonalizable. The similarity transformation of the diagonalization can be pulled out of the power series, and the function only needs to be evaluated for the eigenvalues.

Since most built-in functions (including the hypergeometric ones) are listable, it will be efficient if we can use this listability to our advantage. With a matrix as an argument, listability is initially undesirable, but when we have the eigenvalues as a list it's a great feature.

So here is a more streamlined implementation of the suggestion in the documentation:

matrixEval[func_, arg_?DiagonalizableMatrixQ] := Module[{u, d, e},
  {e, u} = Eigensystem[arg];
  u = ConjugateTranspose[u];
  d = func[e];
  If[! ListQ[d],
   d = func /@ e];
  u.DiagonalMatrix[d].Inverse[u]
  ]

Using the Pauli x matrix as an example, I'll first show how the diagonalizing similarity transform wraps a general function:

Clear[f];
z = PauliMatrix[1];

matrixEval[f[#] &, z] // TraditionalForm

$$\left( \begin{array}{cc} \frac{f(-1)}{2}+\frac{f(1)}{2} & \frac{f(1)}{2}-\frac{f(-1)}{2} \\ \frac{f(1)}{2}-\frac{f(-1)}{2} & \frac{f(-1)}{2}+\frac{f(1)}{2} \\ \end{array} \right)$$

Now replace f by the desired function:

    matrixEval[Hypergeometric2F1[a, b, c, #] &, z] // TraditionalForm

$$\left( \begin{array}{cc} \frac{\, _2F_1(a,b;c;-1)}{2}+\frac{\, _2F_1(a,b;c;1)}{2} & \frac{\, _2F_1(a,b;c;1)}{2}-\frac{\, _2F_1(a,b;c;-1)}{2} \\ \frac{\, _2F_1(a,b;c;1)}{2}-\frac{\, _2F_1(a,b;c;-1)}{2} & \frac{\, _2F_1(a,b;c;-1)}{2}+\frac{\, _2F_1(a,b;c;1)}{2} \\ \end{array} \right)$$

This shows the same structure as above because the diagonalization is the same.

Here is a test with a built-in function that actually has a matrix equivalent:

m = {{3, 2}, {1, 4}};

matrixEval[Exp, m] == MatrixExp[m]

(* ==> True *)

Now it remains to address the question of non-diagonalizable matrix arguments. This can be done in principle as follows:

Find the minimal polynomial of the matrix M. If it is of the form x^k then k is the degree of the matrix, meaning the power for which M^k == 0. This degree is then used in a series expansion of the function, and the matrix can be inserted into that by replacing Power with MatrixPower. Such a matrix is called nilpotent, and the good thing is that power series of such matrices always have at most k terms, so there is no need for infinite sums. I'll make this more concrete if the OP wants to work with such arguments. Probably the best way to actually do this in Mathematica is to use the JordanDecomposition.

So in summary, I would always choose the diagonalization approach rather than trying to rewrite the built in function using its infinite series definition because the latter requires you to first find the appropriate definition and then will also be slow. A series approach is, however, no problem when you have a nilpotent matrix argument, because you can simply apply Series to find the expression you need.

And of course, a power series approach is fine for any finite-dimensional matrix argument if the function in question has a finite number of terms in its series. Another case is where the series terminates but the matrix is infinite-dimensional, as in this answer. Then one can still get pretty good approximate results with a MatrixPower approach using truncated matrices.

Answer 4

Mathematica does not support Hypergeometric functions of matrix arguments. Currently only the cited paper by Plamen and Koev at http://math.mit.edu/~plamen/files/hyper.pdf contains a link to code that implements it in MATLAB.