1
$\begingroup$

Trying to figure out if the double sum $$ f(x,y)=\sum_{n=0}^{\infty}\sum_{m=n}^{\infty}\dfrac{(a)_n\,(b)_n\,(1)_m}{(a)_m\,(b)_m}\dfrac{x^n\, y^m}{n!\,m!}, \;\; \text{where} \;\; (z)_n=z(z+1)\cdots(z+n-1), $$ is a special case of the generalized hypergeometric function (of two variables). For instance, the Kampé de Fériet function seems to have a similar form, but it looks like Mathematica doesn't support this function yet, alas. It does understand the Appell hypergeometric function though, and $f(x,y)$ seems to have a similar form. Interchanging the inner and outer sums didn't prove useful either.

$\endgroup$
  • 2
    $\begingroup$ Does $(1)_m=m!$ ? If so doesn't $(1)_m/m!=1$ ? $\endgroup$ – JimB Feb 17 '18 at 17:06
  • $\begingroup$ @JimB: yes, I added it intentionally to make look more like the Kampe function. Of course that doesn’t fix the problem that the inner sum starts from m=n rather than from m=0. $\endgroup$ – Alex Feb 17 '18 at 18:16
  • $\begingroup$ It seems like a great deal of simplification can take place if summing from $k=m-n=0$ and noting that $(h)_{k+n}=(h)_n (h+n)_k$ and that $(k+n)!=n! (n+1)_k$. $\endgroup$ – JimB Feb 17 '18 at 18:39
3
$\begingroup$

This is more of an extended comment in that the double sum simplifies greatly.

(* Original equation *)
Sum[Pochhammer[a, n] Pochhammer[b, n] Pochhammer[1, m] x^n y^m/
  (Pochhammer[a, m] Pochhammer[b, m] n! m!), {n, 0, ∞}, {m, n, ∞}]

(* Change summation from {m,n,∞} to {k,0,∞} with k=m-n *)
f = Sum[Pochhammer[a, n] Pochhammer[b, n] Pochhammer[1, k + n] x^n y^(k + n)/
  (Pochhammer[a, k + n] Pochhammer[b, k + n] n! (k + n)!), {n, 0, ∞}, {k, 0, ∞}];

(* Make some replacements *)
f = f //. {Pochhammer[h_, k + n] -> Pochhammer[h, n] Pochhammer[h + n, k],
   (k + n)! -> n! Pochhammer[n + 1, k], Pochhammer[1, n] -> n!}

$$\sum _{n=0}^{\infty } \sum _{k=0}^{\infty } \frac{x^n y^{k+n}}{n! (a+n)_k (b+n)_k}$$

Multiply by $1=(1)_k / k!$:

$$\sum _{n=0}^{\infty } \frac{(x y)^n \sum _{k=0}^{\infty } \frac{(1)_k y^k}{k! \left((a+n)_k (b+n)_k\right)}}{n!}$$

and the result is

Sum[HypergeometricPFQ[{1}, {a + n, b + n}, y] (x y)^n/n!, {n, 0, ∞}]

$$\sum _{n=0}^{\infty } \frac{(x y)^n \, _1F_2(1;a+n,b+n;y)}{n!}$$

I don't know if there is further simplification.

$\endgroup$
  • $\begingroup$ Thank you for your effort. I got the same result. I also swapped the two sums around, and got another answer involving the ${}_2F_2$ function. I couldn't simplify it any further either though. Thanks again anyway. $\endgroup$ – Alex Feb 17 '18 at 21:56
  • 1
    $\begingroup$ You can get your result by just separating the summations: Sum[Sum[Pochhammer[a, n] Pochhammer[b, n] Pochhammer[1, m] x^ n y^m/(Pochhammer[a, m] Pochhammer[b, m] n! m!), {m, n, Infinity}], {n, 0, Infinity}] /. Pochhammer[1, n] -> n! $\endgroup$ – Bob Hanlon Jul 18 '18 at 1:05
  • $\begingroup$ @BobHanlon Thanks! That's much simpler. $\endgroup$ – JimB Jul 18 '18 at 1:10
0
$\begingroup$

I'm not sure what is your identification strategy.

z[x_, n_] := Product[x + i, {i, 0, n - 1}]

sum[a_, b_, x_, y_, n_, s_] := Sum[z[a, n] z[b, n] z[1, m] x^n x^m/(z[a, m] z[b, m] n! m!), {m, n, s}]

f[a_, b_, x_, y_, q_, s_] := Sum[sum[a, b, x, y, n, s], {n, 0, q}]

Evaluating the above definitions show that when eg a=b=1,

With[{a = 1., b = 1., s = 13},
  f[a, b, x, y, s, s] // Chop
 ]

$f(x,y)$ seems to converge to the following polynomial

1 + 1. x + 1.25 x^2 + 0.277778 x^3 + 0.529514 x^4 + 0.0573611 x^5 +
0.17021 x^6 + 0.0105575 x^7 + 0.0420872 x^8 + 0.00167832 x^9 +  
0.00837987 x^10 + 0.00023243 x^11 + 0.00139363 x^12 + 0.0000284187 x^13 
+ 0.000198856 x^14 + 3.10568*10^-6 x^15 +  0.0000248399 x^16 + 
3.06576*10^-7 x^17 + 2.7588*10^-6 x^18 +  2.75826*10^-8 x^19 + 
2.75801*10^-7 x^20 + 2.27905*10^-9 x^21 + 2.50679*10^-8 x^22 + 
1.74067*10^-10 x^23 + 2.08871*10^-9 x^24 +  1.6059*10^-10 x^26

For anything n,m>13 the coefficients get chopped off. Hope this helps.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.