Using select to pick out elements of nested lists in an odd way

Question

Suppose I have a nested list such as,

{{{A, B}, {A, D}}, {{C, D}, {A, A}, {H, A}}, {{A, H}}}

Where the elements of interest are,

{{A, B}, {A, D}}

{{C, D}, {A, A}, {H, A}}

{{A, H}}

How would I use select to pick up only elements that contain two or more As in the first part of their sub-elements. In this example I would want the following as an output,

{{A,B},{A,D}}

Answer 1

list = {{{a, b}, {a, d}}, {{c, d}, {a, a}, {h, a}}, {{a, h}}}

Pick[list, Count[#[[All, 1]], a] >= 2 & /@ list]

or

Select[list, Count[#[[All, 1]], a] >= 2 &]

or

Cases[list, _?(Count[#[[All, 1]], a] >= 2 &)]

or

DeleteCases[list, _?(! Count[#[[All, 1]], a] >= 2 &)]

all give

{{{a, b}, {a, d}}}

Answer 2

I chose a slightly different formulation:

expr = {{{A, B}, {A, D}}, {{C, D}, {A, A}, {H, A}}, {{A, H}}};

Select[expr, Count[#, {A, _}] > 1 &]

{{{A, B}, {A, D}}}

I will note that this form is faster all four in the Accepted answer:

list = RandomChoice[CharacterRange["A", "H"], {500000, 3, 2}];

Select[list, Count[#, {"A", _}] > 1 &]                  // Timing // First

Pick[list, Count[#[[All, 1]], "A"] >= 2 & /@ list]      // Timing // First
Select[list, Count[#[[All, 1]], "A"] >= 2 &]            // Timing // First
Cases[list, _?(Count[#[[All, 1]], "A"] >= 2 &)]         // Timing // First
DeleteCases[list, _?(! Count[#[[All, 1]], "A"] >= 2 &)] // Timing // First

0.592804

0.795605
0.811205
0.936006
1.060807

Answer 3

list = {{{A, B}, {A, D}}, {{C, D}, {A, A}, {H, A}}, {{A, H}}};

---

Using Position and Extract:

Extract[#, Position[#, m_?MatrixQ /; Count[m[[All, 1]], A] > 1]] &@list

(*{{{A, B}, {A, D}}}*)

Or using Replace:

Replace[list, m_?MatrixQ /; Count[m[[All, 1]], A] <= 1 :> Nothing, {1}]

(*{{{A, B}, {A, D}}}*)

Answer 4

list = {{{a, b}, {a, d}}, {{c, d}, {a, a}, {h, a}}, {{a, h}}};

p = Position[list, x_ /; Count[First /@ x, a] <= 1, 1, Heads -> False]

{{2}, {3}}

Delete[p] @ list

{{{a, b}, {a, d}}}

MapAt[Nothing, p] @ list

{{{a, b}, {a, d}}}

Answer 5

list = {{{A, B}, {A, D}}, {{C, D}, {A, A}, {H, A}}, {{A, H}}};

If[Count[First /@ #, A] >= 2, #, ## &[]] & /@ list

{{{A, B}, {A, D}}}