1
$\begingroup$

Could someone explain why Mathematica can't finish computing this limit (this is a limit of an array, when n -> Infinity (n is an integer), whose elements are area-integrals as shown):

 Limit[Integrate[(x^(2n) + y^(2n)) Boole[x^(2n) + y^(2n) < 1], {x, -1, 1}, {y, -1, 1}], n -> Infinity]

In the case when n=2, the integral is Pi/2, for n=4 it is (2 Gamma[1/4] Gamma[5/4])/(3 Sqrt[\[Pi]])

Thanx

$\endgroup$
2
  • $\begingroup$ Your integrand does give values for some n, but not for others. For example, n=2.1 gives a revealing error. Do you mean for n to be integer? $\endgroup$
    – bill s
    Jan 31, 2014 at 14:27
  • $\begingroup$ Yes, n is an integer, sorry I forgot to specify. $\endgroup$ Jan 31, 2014 at 17:27

2 Answers 2

2
$\begingroup$

I can get the integral by using the first quadrant (for positivity), placing an assumption on n, and recasting without Boole (I don't know why that was needed).

in = 4 Integrate[(x^(2 n) + y^(2 n)), {x, 0, 1}, {y, 
    0, (1 - x^(2 n))^(1/(2*n))}, Assumptions -> n >= 1]

(* Out[112]= (2^(2 - 1/n) Sqrt[\[Pi]]
  Gamma[1 + 1/(2 n)])/((1 + n) Gamma[(1 + n)/(2 n)]) *)

As @Belisarius notes, the limit is now straightforward.

Limit[in, n -> Infinity]

(* t[113]= 0 *)
$\endgroup$
2
  • $\begingroup$ The Boole is there to specify the area over which an integral is computed (i think this is one way to do that). For example when n=2 the area is a circle with unit area, centered at the origin. $\endgroup$ Jan 31, 2014 at 17:38
  • $\begingroup$ I realize why you had the Boole there. This is a perfectly appropriate usage but, for whatever reason, Integrate did not seem able to handle it. That's why I recast with the more awkward endpoint of integration. $\endgroup$ Jan 31, 2014 at 17:57
1
$\begingroup$

By manual inspection I got a closed formula for your integral:

s[n_] := 2/(n + 1) Gamma[1/(2 n)] Gamma[(2  n + 1)/(2 n)]/Gamma[1/n]
f[n_] := Integrate[(x^(2 n) + y^(2 n)) Boole[x^(2 n) + y^(2 n) < 1], {x, -1, 1}, {y, -1, 1}]

For example

s[16] == f[16]
(*
 True
*)

Plot[s[x], {x, 1, 100}]

Mathematica graphics

So

Limit[s[n], n -> Infinity]
(*
 0
*)
$\endgroup$
1
  • $\begingroup$ Thanks, seems this really goes to zero, which is not what I had expected. $\endgroup$ Jan 31, 2014 at 17:47

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.