Drawing an arrow pointing at the "Enable Dynamics" button

Question

Sometimes my students are given Mathematica notebooks as part of an assignment, and asked to go through some demonstrations contained in the .nb file. A lot of times I get complaints that the "graphs aren't showing up" or "all I see is lines of code". The problem usually is that they haven't enabled dynamics on that particular notebook.

What I'd like to do is have an arrow contained in the notebook that points directly at the "Enable Dynamics" button which shows when a notebook is opened. Then, once the button is clicked, the arrow disappears.

I know how to draw an arrow, but what I don't know how to do is:

1. Have that arrow point to the corner of the notebook window, where the button is;
2. have that arrow disappear once the button is clicked.

Any help or pointers on this would be sincerely appreciated!

Answer 1

I would approach this problem a bit differently. I would provide each such notebook with an initialization button at its top, right under its title, if any. By pressing this button, the dynamic apdating would be enabled. How to do it technically, is already in the comment of belisarius. The further is only a question of a design. The latter should be catching attention, so that even a lazy student would immediately notice it. That depends, of course, of a personal taste of yours. I would propose the following:

    Button[Style["Initialize: press me before you start", Red, Bold], 
 FrontEndExecute[FrontEndToken["ToggleDynamicUpdating"]], 
 ImageSize -> {350, 20}]

When you prepare the notebook, evaluate once this code. The button will appear in the output cell. I propose to select then the cell bracket and to click Menu/Format/Text Alignment/Align Center. The button will be centered. You then can collapse the input cell (go to Menu/Cell/Cell Properties and uncheck "Open"). The notebook will look like this: As one reasonable extension, you might want to include evaluation of initialization cells into the same button:

    Button[Style["Initialize: press me before you start", Red, 
  Bold], (FrontEndExecute[FrontEndToken["ToggleDynamicUpdating"]];
  FrontEndExecute[FrontEndToken["EvaluateInitialization"]]), 
 ImageSize -> {350, 20}]

Have fun.

Answer 2

According to my rough test, the DynamicUpdating option used at the Notebook level can override the global setting. To demonstrate that, here is a simple test.

1. Start a fresh new Mathematica, and goto Evaluation menu, uncheck the Dynamic Updating Enabled term.

   Or goto the Option Inspector, select Global Preference, then set Cell Options -> Evaluation Options -> "DynamicUpdating" to False.

   

   Note: According to Jacob Akkerboom, this is equivalent to SetOptions[$FrontEnd, DynamicUpdating -> False]. Also note it overrides the Dynamic Updating Enabled menu setting.

2. Using any text editor to create the following two Notebook files:

   

   Notebook[{Cell[BoxData[DynamicBox[ToBoxes[Date[],StandardForm],UpdateInterval:>0]],"Output"]}]
   

   ---

   Notebook[{Cell[BoxData[DynamicBox[ToBoxes[Date[],StandardForm],UpdateInterval:>0]],"Output"]},DynamicUpdating->True]
   

3. Open them in Mathematica, we can see despite the dynamic-updating being globally disabled, the later Notebook still functions.

   

Notebook Security

About Kuba's comment on the safety issue, I think it won't be a problem, as when the nb file is NOT on a "TrustedPath", Mathematica will always detect unsafe dynamic content and raise an alarm if there is any, even the global dynamic-updating is set to True.

Here is a simple test.

1. Set SetOptions[$FrontEnd, DynamicUpdating -> True].

2. Using any text editor to create the following two Notebook files, which contain unsafe dynamic function FileNames[ ]:

   Notebook[{Cell[BoxData[DynamicBox[ToBoxes[FileNames[],StandardForm],UpdateInterval:>0]],"Output"]}]
   

   ---

   Notebook[{Cell[BoxData[DynamicBox[ToBoxes[FileNames[],StandardForm],UpdateInterval:>0]],"Output"]},DynamicUpdating->True]
   

3. Open them in Mathematica, we can see both of them being alerted.

   

So in my opinion, it should be as safe as other method to use this DynamicUpdating option at the Notebook level.

Note: There IS a potential unsafe issue as described by Jacob Akkerboom. That is, when there is an alarm bar as shown above, you can ignore it but just run some code with dynamic function (like as simple as Dynamic[]) to enable the dynamic-updating, which also cause the former forbiden dynamic Cell to work, which may contain harmful code!

Answer 3

How about a cell at the top of the notebook containing a message to click the button, which then deletes itself when dynamic updating is enabled:

DynamicWrapper[Style["Click the stupid button! \[UpArrow]", "Title"], 
SelectionMove[EvaluationNotebook[], Before, Notebook];
SelectionMove[EvaluationNotebook[], Next, Cell];
NotebookDelete[]]

Note that the input cell will eat itself as soon as you evaluate it. If you then close and save the notebook, then re-open it, you should find that the message disappears after the enable dynamics button is clicked.