2
$\begingroup$

I'm trying to evaluate $\lim_{e\to 0} \, \frac{i}{e}\int_{\pi }^0 \frac{1-\exp (i e \exp (i \theta ))}{\exp (i \theta )} \, d\theta$ with Mathematica 9.0.1.0 on OS X.

However, I get "Undefined" for this input:

Limit[I/e Integrate[(1 - Exp[I e Exp[I θ]])/Exp[I θ], {θ, π, 0}], e -> 0]

We can see numerically that the correct answer is $-\pi$ by using this code:

With[{e = 0.000001}, I/e NIntegrate[(1 - Exp[I e Exp[I θ]])/Exp[I θ], {θ, π, 0}] ] // Chop

What goes wrong in this process? Is it possible to get the correct result?

$\endgroup$
  • $\begingroup$ Giving an assumption on that epsilon will help. Limit[ I/eps*Integrate[(1 - Exp[I eps Exp[I \[Theta]]])/ Exp[I \[Theta]], {\[Theta], \[Pi], 0}, Assumptions -> 0 < eps < 1/1000], eps -> 0] Out[329]= -\[Pi] $\endgroup$ – Daniel Lichtblau Oct 28 '13 at 14:57
2
$\begingroup$

There seems to be some issue with the definite integral. But you can easily work around it by using indefinite integration then evaluate for the limit of integration (replaced your $\theta$ with $x$ to paste here)

 r = Integrate[(1 - Exp[I e Exp[I x]])/Exp[I x], x];
-((r /. x -> Pi) - (r /. x -> 0));
Limit[I/e*%, e -> 0]

Mathematica graphics

Mathematica 9.01 on windows

One can see something is strange, by doing:

r = Integrate[(1 - Exp[I e Exp[I x]])/Exp[I x], {x, \[Pi], 0}]
Assuming[Re[e] <= 0 && Im[e] == 0, Limit[I/e*r, e -> 0]]

Where did this 1/4096 value come from?

Mathematica graphics

$\endgroup$
2
$\begingroup$
Assuming[s \[Element] Reals && s > 0, 
 Limit[I/s Integrate[(1 - Exp[I s Exp[I t]])/Exp[I t], {t, Pi, 0}], 
  s -> 0]]

yields $-\pi$ (Mathematica 9.0). The integral yields a conditional expression which renders limit undefined without declaring assumptions. There is a difficulty (probably related to periodicity) if you try to bypass by using generate conditions to false. The limit returned is $\pi$.

$\endgroup$
0
$\begingroup$

You can use AsymptoticIntegrate:

I/e AsymptoticIntegrate[(1 - Exp[I e Exp[I θ]])/Exp[I θ, {θ, π, 0}, {e, 0, 1}]

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.