How to make Mathematica able to integrate $\int_{-\infty}^\infty \frac{e^{ikx}}{(x+ia)^3} dx = i\pi k^2 e^{ka} \theta(-k)$ for $a>0$?

Question

I want to evaluate an integral which is essentially a sum of the form $\lim_{a\to 0^+}\int_{-\infty}^\infty \frac{e^{ikx}}{(x+ia)^m} dx$, where $k\in\mathbb R$ and $m\in\mathbb N$. By the residue theorem, we can easily evaluate the integral $$\int_{-\infty}^\infty \frac{e^{ikx}}{(x+ia)^m} dx = -\frac{2\pi i}{(m-1)!} (ik)^{m-1} e^{ka} \theta(-k), \tag{*}$$ where $\theta$ is the Heaviside function. In particular, letting $a\to 0^+$, we simplify $$\lim_{a\to 0^+}\int_{-\infty}^\infty \frac{e^{ikx}}{(x+ia)^m} dx = -\frac{2\pi i}{(m-1)!} (ik)^{m-1} \theta(-k).$$

Now, I have a somewhat complicated expression, which is obtained from other Mathematica calculation:

$Assumptions = {a > 0, k1 > 0, k2 > 0, k3 > 0, k1 + k2 - k3 > 0}
exp = 1/(x3 + I a)^3 E^(-I (k1 + k2 - 
    k3) x3) (-3 I (-1 + E^(I k1 x3)) (-1 + E^(I k2 x3)) k2 + 
   3 k1 (I + I E^(I (k1 + k2) x3) + E^(I k1 x3) (-I + k2 x3) - 
      E^(I k2 x3) (I + k2 x3)))

Question: I want to evaluate

Integrate[exp, {x3, -Infinity, Infinity}]/.{a->0}

Although exp is complicated, it is a sum of the form $(*)$, so it should be calculable. However, Mathematica cannot evaluate this in a reasonable time.

I think I have to somehow "teach" Mathematica to use $(*)$. How can I do this?

Answer 1

Maybe this?:

Assuming[{a > 0, k1 > 0, k2 > 0, k3 > 0, k1 + k2 - k3 > 0},
 Total@Map[
   With[{e = First@Cases[#, E^_]}, 
     Sqrt[2 Pi] FourierTransform[#/e, x3, k] /. k -> I*Last[e]/x3] &,
   Simplify /@ List @@ Expand[exp]]
 ]
(*
-3 E^(-a k3) k1 k3^2 \[Pi] HeavisideTheta[k3] +
 3 E^(-a k3) k2 k3^2 \[Pi] HeavisideTheta[k3] -
 3 E^(a (k1 - k3))
   k1 k2 (2 + a (k1 - k3)) (k1 - k3) \[Pi] HeavisideTheta[-k1 + k3] +
 3 E^(a (k1 - k3)) k1 (k1 - k3)^2 \[Pi] HeavisideTheta[-k1 + k3] -
 3 E^(a (k1 - k3)) k2 (k1 - k3)^2 \[Pi] HeavisideTheta[-k1 + k3] +
 3 E^(a (k2 - k3))
   k1 k2 (2 + a (k2 - k3)) (k2 - k3) \[Pi] HeavisideTheta[-k2 + k3] +
 3 E^(a (k2 - k3)) k1 (k2 - k3)^2 \[Pi] HeavisideTheta[-k2 + k3] -
 3 E^(a (k2 - k3)) k2 (k2 - k3)^2 \[Pi] HeavisideTheta[-k2 + k3] -
 3 E^(a (k1 + k2 - k3))
   k1 (k1 + k2 - k3)^2 \[Pi] HeavisideTheta[-k1 - k2 + k3] +
 3 E^(a (k1 + k2 - k3))
   k2 (k1 + k2 - k3)^2 \[Pi] HeavisideTheta[-k1 - k2 + k3]
*)