How to find intersecting linear equations between two lists?

Question

I have two lists of linear equations:

list1 = {x - y == 0, x + 2y == 0, 3x - y == 0}  
list2 = {-x + y == 0, -x - 2y == 0, 3x - y == 0,  3x - 2y == 0} 

I want to check for intersections between these two lists of equations.
Clearly, x - y == 0 and -x + y == 0 represent the same equation, and x + 2y == 0 and -x - 2y == 0 also represent the same equation. However, if I compare them directly, they don't appear to be equal.

So, how can I find the intersecting equations?
The expected result would be something like this: {x - y == 0, x + 2y == 0, 3x - y == 0} or their equivalent forms.

Answer 1

Can intersect using Intersection once all right-hand-sides are zero. Just use Together on the quotient of left-hand-sides as the SameTest. The result will contain an element from each equivalence class that occurs in both lists.

list1 = {x - y == 0, x + 2 y == 0, 3 x - y == 0};
list2 = {-x + y == 0, -x - 2 y == 0, 3 x - y == 0, 3 x - 2 y == 0};
newl1 = Map[SubtractSides, list1];
newl2 = Map[SubtractSides, list2];
Intersection[newl1, newl2, 
 SameTest -> (NumberQ[Together[#1[[1]]/#2[[1]]]] &)]

(* Out[12]= {x - y == 0, 3 x - y == 0, x + 2 y == 0} *)

Answer 2

To get an overview, draw a picture:

list1 = {x - y == 0, x + 2 y == 0, 3 x - y == 0}
list2 = {-x + y == 0, -x - 2 y == 0, 3 x - y == 0, 3 x - 2 y == 0}

ContourPlot[list1, {x, -d, d}, {y, -1, 1}]
ContourPlot[list2, {x, -d, d}, {y, -1, 1}]

It is clear that list2 contains an additional equation as last item. Therefore to prove this:

list1-Most[list2] //Simplify

{0, 0, 0

And the intersection point is:

Solve[list1[[1 ;; 2]], {x, y}]

{{x -> 0, y -> 0}}

Answer 3

Reduce the list

SubtractSides/@List@@FullSimplify[Reduce[Or@@Join[list1,list2]]]
(* {x + 2 y == 0, 3 x - y == 0, 3 x - 2 y == 0, x - y == 0}  *)

Sort by slope

SortBy[%,D[#[[1]],x]/D[#[[1]],y] &]
(* {3 x - y == 0, 3 x - 2 y == 0, x - y == 0, x + 2 y == 0} *)

Plot

Plot[
   Evaluate[
      ReplaceAll[y,First@Solve[#,y]]& /@ %
   ]
   , {x, -10,10}
   , PlotLegends->%
]

Answer 4

• Follow the idea by @Daniel Lichtblau ( +1 );
• Using RegionEqual( or ForAll[{x, y}, Equivalent[expr1, expr2]] // Resolve);

Clear["Global`*"];
list1 = {x - y == 0, x + 2 y == 0, 3 x - y == 0};
list2 = {-x + y == 0, -x - 2 y == 0, 3 x - y == 0, 3 x - 2 y == 0};
list1 = ImplicitRegion[#, {x, y}] & /@ list1;
list2 = ImplicitRegion[#, {x, y}] & /@ list2;
Intersection[list1, list2, SameTest -> RegionEqual ][[;; , 1]]

{x - y == 0, 3 x - y == 0, x + 2 y == 0}

• test another example.

Clear["Global`*"];
list1 = {x - y == 0, x + 2 y == 0, 
   3 x - y == 0, (x - 1)^2 + 2 (y - 3)^2 - 1 == 0, 
   Abs[x] + Abs[y] == 1, x == 3 || x == 2};
list2 = {-x + y == 0, -x - 2 y == 0, 3 x - y == 0, 3 x - 2 y == 0, 
   18 - 2 x + x^2 - 12 y + 2 y^2 == 0, (Abs[x] + Abs[y])^2 == 
    1, (x - 3) (x - 2) == 0};
list1 = ImplicitRegion[#, {x, y}] & /@ list1;
list2 = ImplicitRegion[#, {x, y}] & /@ list2;
Intersection[list1, list2, SameTest -> RegionEqual][[;; , 1]]

{-1 + (-1 + x)^2 + 2 (-3 + y)^2 == 0, x - y == 0, 3 x - y == 0, x + 2 y == 0, Abs[x] + Abs[y] == 1, x == 3 || x == 2}

Answer 5

Something bland (as equations are linear 2D:

list1 = {x - y == 0, x + 2 y == 0, 3 x - y == 0};
list2 = {-x + y == 0, -x - 2 y == 0, 3 x - y == 0, 3 x - 2 y == 0};
Intersection[list1, list2, 
 SameTest -> (SolveValues[#1, y][[1]] === SolveValues[#2, y][[1]] &)]

yields: {x - y == 0, 3 x - y == 0, x + 2 y == 0}