2
$\begingroup$

Following my previous question How to transform this MeijerG $G_{3,3}^{2,3}$ into a hypergeometric function $ _2F_1 $, I transformed a MeijerG function $G_{3,3}^{2,3}$ below into a combination of hypergeometric function $ _2F_1 $

 y = y = MeijerG[{{(1 - k)/2, 2 - k/2, -(k/2)}, {}}, {{0, 1/2}, {(1 - k)/2}}, (k - z)/z, 1/2]
 FunctionExpand[y] // FullSimplify

(* Sqrt[\[Pi]] (Gamma[-1 + \[Kappa]/2] Gamma[1 + \[Kappa]/2] Hypergeometric2F1[1/2 (-2 + \[Kappa]), (2 + \[Kappa])/2, 1/2, (z - \[Kappa])^2/z^2] + (2 Gamma[1/2 (-1 + \[Kappa])] Gamma[(3 + \[Kappa])/2] (\[Kappa] (-2 z + \[Kappa]) Hypergeometric2F1[1/2 (-1 + \[Kappa]), (3 + \[Kappa])/2, -(1/2), (z - \[Kappa])^2/z^2] - (-4 z \[Kappa] (1 + \[Kappa]) + 2 \[Kappa]^2 (1 + \[Kappa]) + z^2 (1 + 2 \[Kappa])) Hypergeometric2F1[1/2 (-1 + \[Kappa]), (3 + \[Kappa])/2, 1/2, (z - \[Kappa])^2/z^2]))/(z (z - \[Kappa]) (-4 + \[Kappa]^2)))  *)

$$\frac{y}{\sqrt{\pi}}=g_1+\frac{2\kappa (\kappa -2 z)}{\left(\kappa ^2-4\right) z (z-\kappa )}g_2 -\frac{2 \left(2 \kappa ^2 (\kappa +1)+(2 \kappa +1) z^2-4 \kappa (\kappa +1) z\right)}{\left(\kappa ^2-4\right) z (z-\kappa )}g_3,\\ g_1=\Gamma \left(\frac{\kappa -2 }{2}\right) \Gamma \left(\frac{\kappa +1 }{2}\right)\, _2F_1\left(\frac{\kappa -2}{2},\frac{\kappa +2}{2};\frac{1}{2};u\right),\\ g_2=\Gamma \left(\frac{\kappa -1}{2}\right) \Gamma \left(\frac{\kappa +3}{2}\right)\, _2F_1\left(\frac{\kappa -1}{2},\frac{\kappa +3}{2};-\frac{1}{2};u\right),\\ g_3=\Gamma \left(\frac{\kappa -1}{2}\right) \Gamma \left(\frac{\kappa +3}{2}\right)\, _2F_1\left(\frac{\kappa -1}{2},\frac{\kappa +3}{2};\frac{1}{2};u\right),\\ u=\frac{(z-\kappa )^2}{z^2}.$$

Now I want to transform this combination of $ _2F_1 $ functions into a single $ _2F_1 $ function?

Sqrt[\[Pi]] (Gamma[-1 + \[Kappa]/2] Gamma[1 + \[Kappa]/2] Hypergeometric2F1[1/2 (-2 + \[Kappa]), (2 + \[Kappa])/2, 1/2, (z - \[Kappa])^2/z^2] + (2 Gamma[1/2 (-1 + \[Kappa])] Gamma[(3 + \[Kappa])/2] (\[Kappa] (-2 z + \[Kappa]) Hypergeometric2F1[1/2 (-1 + \[Kappa]), (3 + \[Kappa])/2, -(1/2), (z - \[Kappa])^2/z^2] - (-4 z \[Kappa] (1 + \[Kappa]) + 
     2 \[Kappa]^2 (1 + \[Kappa]) + z^2 (1 + 2 \[Kappa])) Hypergeometric2F1[
    1/2 (-1 + \[Kappa]), (3 + \[Kappa])/2, 1/2, (z - \[Kappa])^2/
    z^2]))/(z (z - \[Kappa]) (-4 + \[Kappa]^2)))

Can you do this please?

Improve this question
$\endgroup$
3
  • 1
    $\begingroup$ You seems to be confident that such transformation is possible. Are there any hints on why it might be feasible. Do you have some transformation in mind? $\endgroup$
    – yarchik
    Commented Jun 17 at 22:44
  • $\begingroup$ @yarchik according to one of the equations (15) from Abramowitz and Stegun's Handbook, I think it's possible $\endgroup$
    – Gallagher
    Commented Jun 17 at 22:53
  • $\begingroup$ The problem is that in the book all formulas for $F(a, b, c, x)$ increment or decrement $a$, $b$, or $c$ by $\pm1$. In your example the increment is $\pm1/2$. $\endgroup$
    – yarchik
    Commented Jun 18 at 5:27

2 Answers 2

Reset to default
2
$\begingroup$ 
$Version

(* "14.0.0 for Mac OS X ARM (64-bit) (December 13, 2023)" *)

Clear["Global`*"]

y[k_, z_] = 
  MeijerG[{{(1 - k)/2, 2 - k/2, -(k/2)}, {}}, {{0, 
       1/2}, {(1 - k)/2}}, (k - z)/z, 1/2] // FunctionExpand // FullSimplify;

Using approach provided by Mariusz Iwaniuk

y2[k_, z_] = 
 System`MeijerGDump`MeijerGToSums[
    MeijerG[{{(1 - k)/2, 2 - k/2, -(k/2)}, {}}, {{0, 
       1/2}, {(1 - k)/2}}, (k - z)/z, 1/2], j] // ReleaseHold // FullSimplify

(* Sqrt[π] (Gamma[-1 + k/2] Gamma[1 + k/2] Hypergeometric2F1[1/2 (-2 + k), (
     2 + k)/2, 1/2, (k - z)^2/z^2] + (1/z)
   2 (-k + z) Gamma[1/2 (-1 + k)] Gamma[(3 + k)/2] Hypergeometric2F1[
     1/2 (-1 + k), (3 + k)/2, 3/2, (k - z)^2/z^2]) *)

The representations are equivalent

y[k, z] == y2[k, z] // FullSimplify

(* True *)

For {k = 1000, z = 100}, the imaginary part is zero

Block[{$MaxExtraPrecision = 500},
 {Im[y[1000, 100]] == 0, Im[y2[1000, 100]] == 0} // N[#, 100] &]

(* {True, True} *)

And the real part is

Block[{$MaxExtraPrecision = 500},
 {Re[y[1000, 100]], Re[y2[1000, 100]]} // N[#, 100] & // N]

(* {3.401112093366100*10^1263, 3.401112093366100*10^1263} *)

a large number.

Improve this answer
$\endgroup$
1
6
$\begingroup$

It can be simplifed more.

Using undocumented command:

A = System`MeijerGDump`MeijerGToSums[MeijerG[{{(1 - k)/2, 2 - k/2, -(k/2)}, {}}, {{0, 1/2}, {(1 - k)/2}}, (k - z)/z, 1/2], j]

ReleaseHold[A[[1, 1, 1]]] // FullSimplify (*For: Abs[(k - z)/z] <= 1 *)

(*Sqrt[\[Pi]] (Gamma[-1 + k/2] Gamma[1 + k/2] Hypergeometric2F1[
 1/2 (-2 + k), (2 + k)/2, 1/2, (k - z)^2/z^2] + (
2 (-k + z) Gamma[1/2 (-1 + k)] Gamma[(3 + k)/2]*Hypergeometric2F1[
 1/2 (-1 + k), (3 + k)/2, 3/2, (k - z)^2/z^2])/z)*)

 ReleaseHold[A[[1, 2, 1]]] // FullSimplify (*For: Abs[(k - z)/z] > 1*)

 (*Sqrt[\[Pi]] (Gamma[-1 + k/2] Gamma[1 + k/2] Hypergeometric2F1[
 1/2 (-2 + k), (2 + k)/2, 1/2, (k - z)^2/z^2] + (
 2 (-k + z) Gamma[1/2 (-1 + k)] Gamma[(3 + k)/2] 
 Hypergeometric2F1[
 1/2 (-1 + k), (3 + k)/2, 3/2, (k - z)^2/z^2])/z)*)
Improve this answer
$\endgroup$
2
  • 1
    $\begingroup$ It looks like Eq. (5.2.27) of the Abramowitz and Stegun's Handbook. $\endgroup$
    – yarchik
    Commented Jun 18 at 9:16
  • $\begingroup$ @Mariusz Iwaniuk Thank you so much, even though I was looking for a single term in 2F1. However a simple numerical application for A[[1, 1, 1]] or A[[1, 2, 1]] for z=100 and k=1000 gives Indeterminate, you don't see a solution? $\endgroup$
    – Gallagher
    Commented Jun 18 at 14:20

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.