6
$\begingroup$

How to prove with the help of Mathematica the following statement?

$$ {}_2F_1\left(\frac{2}{3},\frac{2}{3};\frac{5}{3};-1\right)=\frac{\pi -3 \sqrt{3} \log \left(\sqrt[3]{2}-1\right)-6 \tan^{-1}\left(\frac{1+2^{2/3}}{\sqrt{3}}\right)}{3 \sqrt{3}} $$

FullSimplify[
 Hypergeometric2F1[2/3, 2/3, 5/3, -1] 
   - ((\[Pi] - 6 ArcTan[(1 + 2^(2/3))/Sqrt[3]] - 3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3]))]

is returned without simplifications.

Background: There are several reasons to study this value. On the one side, it can be easily represented as a definite integral: $$ {}_2F_1\left(\frac{2}{3},\frac{2}{3};\frac{5}{3};-1\right) = \frac{\Gamma(5/3)}{\Gamma(2/3)} \int_0^\infty \frac{1}{(1 + t) (2 + t)^{2/3}} dt. $$ On the other side, there are many cases where hypergeometric functions can be evaluated at $z = −1$ by using a transformation to change $z = −1$ to $z = 1$ and then using Gauss's theorem, which Mathematica certainly "knowns", to evaluate the result. Quadratic and cubic transformations come into question, but I cannot seem to find the right identity. I hope that Mathematica knows these transformations internally.

$\endgroup$
4
  • 3
    $\begingroup$ Block[{$MaxExtraPrecision = 500}, Hypergeometric2F1[2/3, 2/3, 5/3, -1] - ((\[Pi] - 6 ArcTan[(1 + 2^(2/3))/Sqrt[3]] - 3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3])) // N[#, 100] &] $\endgroup$
    – Bob Hanlon
    Jun 30, 2023 at 18:42
  • $\begingroup$ What for? Isn't it art for art's sake? $\endgroup$
    – user64494
    Jun 30, 2023 at 18:51
  • 1
    $\begingroup$ The method used here might be useful. $\endgroup$
    – Ghoster
    Jun 30, 2023 at 20:31
  • $\begingroup$ @yarchik: Are your reasons solid? You still don't answer "what for?". You say only about similar identities. $\endgroup$
    – user64494
    Jul 2, 2023 at 17:18

3 Answers 3

3
$\begingroup$

There is an identity $15.6.1$ in NIST Digital Library of Mathematical Functions or in Wolfram Functions Site (mind appropriate definitions therein!) $$_2F_1\left(a,b;c;z\right)=\frac{\Gamma\left(c\right)}{\Gamma\left(b\right)\Gamma\left(c-b% \right)}\int_{0}^{1}\frac{t^{b-1}(1-t)^{c-b-1}}{(1-z\;t)^{a}}\,\mathrm{d}t$$

Mathematica knows this identity

FullSimplify[ Hypergeometric2F1[a, b, c, z] == (Gamma[
  c]/(Gamma[b] Gamma[c - b])) Integrate[(t^(b - 1) (1 - t)^(c - b - 1)
    )/(1 - t z)^a, {t, 0, 1}], 
  Re[c] > Re[b] > 0 && Abs[Arg[1 - z]] < Pi && Re[z] <= 1]
True

We are interested in $a=b=\frac{2}{3},\;c=\frac{5}{3},\;z=-1\;$ case.

Integrate[1/(t^(1/3) (1 + t)^(2/3)), {t, 0, 1}]
3/2 Hypergeometric2F1[2/3, 2/3, 5/3, -1]

We can change the variable $t$ into $x$: $\quad t^{\frac{2}{3}}=x$ and so $$_2F_1\left(\frac{2}{3},\frac{2}{3};\frac{5}{3};-1\right)=\frac{2}{3}\int_0^1 \frac{1}{t^{\frac{1}{3}}(1+t)^{\frac{2}{3}}}\,\mathrm{d}t=\int_0^1 \frac{1}{(1+x^{\frac{3}{2}})^{\frac{2}{3}}}\,\mathrm{d}x$$ The last integral can be simply calculated in Mathematica 13.0.1

Integrate[1/(1 + x^(3/2))^(2/3), {x, 0, 1}]
1/3 (-2 Sqrt[3] ArcCot[(1 + 2 2^(1/3))/Sqrt[3]] - 2 Log[-1 + 2^(1/3)]
      + Log[1 + 2^(1/3) + 2^(2/3)])

and in fact we have

FullSimplify[
  1/3 (-2 Sqrt[3] ArcCot[(1 + 2 2^(1/3))/Sqrt[3]] - 
         2 Log[-1 + 2^(1/3)] + Log[1 + 2^(1/3) + 2^(2/3)]) == 
  (Pi - 6 ArcTan[(1 + 2^(2/3))/Sqrt[3]] - 3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3])]
 True

i.e. enter image description here

Handling of special functions by any computer algebra system brings several issues, e.g. how to get a specific formula among many possibilities when we expect automatic proceeding of the system? This addresses a number of technical problems behind the scene developing an agile computer system. I guess Mathematica gets ahead fulfilling these requirements.

Edit for earlier versions

I have checked in version 12.3.1

Integrate[1/(1 + x^(3/2))^(2/3), x]
Integrate[1/(1 + x^(3/2))^(2/3), {x, 0, 1}]
x Hypergeometric2F1[2/3, 2/3, 5/3, -x^(3/2)]
Hypergeometric2F1[2/3, 2/3, 5/3, -1]

Nonetheless we can define:

int[x_] := -((2 ArcTan[(Sqrt[3] Sqrt[x])/(Sqrt[x] + 2 (1 + x^(3/2))^(1/3)
  )])/Sqrt[3]) - 2/3 Log[-Sqrt[x] + (1 + x^(3/2))^(1/3)] + 
    1/3 Log[x + Sqrt[x] (1 + x^(3/2))^(1/3) + (1 + x^(3/2))^(2/3)]

then

int[1] - int[0] // FullSimplify

yields the result of Integrate[1/(1 + x^(3/2))^(2/3), {x, 0, 1}] in version 13.0.1 and

D[int[x], x] // FullSimplify
 1/(1 + x^(3/2))^(2/3)
$\endgroup$
3
  • $\begingroup$ What version of Mathematica that are you using? MA 11, for instance, returns result of Integrate[1/(1 + x^(3/2))^(2/3), {x, 0, 1}] in hypergeometric form. $\endgroup$
    – yarchik
    Jul 4, 2023 at 6:46
  • $\begingroup$ Version 13.0.1 returns as demonstrated above. $\endgroup$
    – Artes
    Jul 4, 2023 at 7:11
  • $\begingroup$ Interesting to know that there has been some development in this direction recently. $\endgroup$
    – yarchik
    Jul 4, 2023 at 7:30
0
$\begingroup$

Hypergeometric series are the solution family of linear ODE on (0,1) with polynomial coefficients in $x$. Nearly nothing is known in general.

Identities at a point of the argument for fixed paramters, $x=-1$, generally can be verified by the 0th term of series

     Series[Hypergeometric2F1[2/3, 2/3, 5/3, 
x] - ((\[Pi] - 6 ArcTan[(1 + 2^(2/3))/Sqrt[3]] - 
   3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3])), {x, -1, 0}]

SeriesData[x, -1., {}, 1, 1, 1]  

or by FindRoot

  FindRoot[Hypergeometric2F1[2/3, 2/3, 5/3, x] - ((\[Pi] - 6 ArcTan[(1 + 2^(2/3))/Sqrt[3]] - 
           3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3])), {x, 2}]


   {x -> -1. - 9.14229*10^-20 I}
$\endgroup$
3
  • $\begingroup$ I am getting Series::ztest1: Unable to decide whether numeric quantity is equal to zero. Assuming it is. Do you get some more informative result? $\endgroup$
    – yarchik
    Jul 3, 2023 at 14:35
  • $\begingroup$ Series[Hypergeometric2F1[2/3, 2/3, 5/3, x] - ((\[Pi] - 6 ArcTan[(1 + 2^(2/3))/Sqrt[3]] - 3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3])), {x, -1, 1}] works better. $\endgroup$
    – user64494
    Jul 3, 2023 at 15:23
  • 1
    $\begingroup$ Things in special functions code are under permanent development. My results are from vs 13.3.0 installed yesterday. A vs 6 is unable, too. Workaround: Get Series[ f/value,{x,-1,0}] //N, yieldiing 1.0 with less headache as 0.0 $\endgroup$
    – Roland F
    Jul 3, 2023 at 15:42
0
$\begingroup$

Since I'm just translating Euleros Latin paper De Fractionibus Continuis Observationes, in order to get a feeling of his way of making detections by an extraodinary ability in performeing nearly endless algebraic deformations

Euler Continued Fractions

applied to the original definition of hypergeometric functions as generalized integrals of the form

$$\int_0^1 \frac {dx}{1+x} \to \int_0^1 \frac {x^{n-1}\ dx}{(1+x^m)^{\frac{\nu}{\mu}}}$$

I simply tried his way to confirm equality of infinite expressions

Continued Fraction

For the numerics up to any length, here 128, the continued fractions are equal

 ContinuedFraction[N[((\[Pi]-6 ArcTan[(1 + 2^(2/3))/Sqrt[3]]- 
         3 Sqrt[3] Log[-1 + 2^(1/3)])/(3 Sqrt[3])), 128]] ==
 ContinuedFraction[N[Hypergeometric2F1[2/3, 2/3, 5/3, -1], 128]]

     True

This is of course no proof, any more than Euler's analysis for guessing the nesting function of the parameters in each fractional step.

$\endgroup$

This site is temporarily in read-only mode and not accepting new answers.

Not the answer you're looking for? Browse other questions tagged .