Plotlines don't meet the axes?

Question

I am trying to plot a few functions which have very large numeric outputs. One can however scale the outputs to make the values small. I will paste the function here

Mhawk1[tt_, minit_] = (
  500000000 (30/(37 \[Pi]))^(
   1/3) ((412016053 minit^3 \[Pi])/3750000000000000000000000000 - (
     134745444 tt)/5)^(1/3))/3337^(2/3);

I write one more function that plots the above function till for a given value of minit for values of tt such that the argument inside the radical is greater than or equal to zero.

mhawkplot[minit_] := 
 LogLogPlot[
  Mhawk1[tt, minit], {tt, 0, (412016053 minit^3 \[Pi])/
   101059083000000000000000000000000000}, ImageSize -> Large, 
  PlotRange -> All]

I have to now compare these plots for various values of minit. For example $10^10$ and $10^11$. But the plot for the larger of these two values does no start from $tt = 0$ and does not end where the function becomes zero as well.

p1 = mhawkplot[10^10];

p2 = mhawkplot[10^11];

Show[p1, p2]

Gives the following output

Is there a way to do this better? Any help is greatly appreciated. Thanks.

Answer 1

You may give explicit values for start and end of the plot. But note that Mhawk1 becomes complex for larger values and can therefore not been plotted for all arguments.

Mhawk1[tt_, 
   minit_] = (500000000  (30/(37  \[Pi]))^(1/
        3)  ((412016053  minit^3  \[Pi])/
         3750000000000000000000000000 - (134745444  tt)/5)^(1/3))/
   3337^(2/3);
mhawkplot[minit_, start_, end_] := 
  LogLogPlot[Mhawk1[tt, minit], {tt, start, end}, ImageSize -> Large, 
   PlotRange -> All];

p1 = mhawkplot[10^10, 10, 10^8]
p2 = mhawkplot[10^11, 10, 10^8]
Show[p1, p2]

If you want to end the plot on the x axis, you have to restrict the x and y axes.

Answer 2

Two or three things can fix this: Solving for the value of tt that gives the desired lower bound (none is stated, except a desire that they be the same). (2) Prevent the plotter from a slight offset in from the end points of the plot domain. (3) Finally, set the PlotRange to have the desired lower bound. (Without this, there is a slight difference in the levels of the lower end points, because of the numerical sensitivity of a very steep graph to small changes in the abscissa.)

mhawk1[tt_, 
   minit_] = (500000000  (30/(37  \[Pi]))^(1/
        3)  ((412016053  minit^3  \[Pi])/
         3750000000000000000000000000 - (134745444  tt)/5)^(1/3))/
   3337^(2/3);

mhawkplot[minit_] := LogLogPlot[mhawk1[tt, minit]
  , {tt, 0, t /. First@Solve[mhawk1[t, minit] == 10^6, t]}
  (*,ImageSize->Large*)
  , PlotRange -> {All, {10^6, All}}
  , Method -> {"BoundaryOffset" -> False}]
    
p1 = mhawkplot[10^10];

p2 = mhawkplot[10^11];

Show[p1, p2]