1
$\begingroup$

How can I plot the image of |z-2| < 1 under the transformation w = z/(z-1)? The expected result should look something like this.

enter image description here

Improve this question
$\endgroup$
4
  • 1
    $\begingroup$ What is the relationship between $x$, $y$, and $z$ in your equations and diagram on the left? $\endgroup$
    – MarcoB
    Commented Dec 1, 2023 at 14:58
  • 2
    $\begingroup$ Take a look at ComplexRegionPlot. Look at the "Mapping Complex Regions" in the "Applications" section. $\endgroup$
    – Gustavo Delfino
    Commented Dec 1, 2023 at 14:59
  • $\begingroup$ @MarcoB z = x + i y and w = u + i v. $\endgroup$
    – internet
    Commented Dec 1, 2023 at 14:59
  • 1
    $\begingroup$ It looks like the numerator of w should be 2, not z. Compare to the 2 in the inequality. So the right picture is correct. $\endgroup$
    – Mike Z.
    Commented Dec 1, 2023 at 19:44

3 Answers 3

Reset to default
6
$\begingroup$
  • We mapping the region ImplicitRegion[Abs[z - 2] < 1, {x, y}] to another region by the z( identity mapping) and 2/(z - 1).
plot=Block[{z = x + I*y}, 
   ParametricPlot[#, {x, y} ∈ 
     ImplicitRegion[Abs[z - 2] < 1, {x, y}], PlotRange -> 4, 
    Axes -> True, Frame -> False, 
    AxesStyle -> Arrowheads[.05]]] & /@ {ReIm[z], ReIm[2/(z - 1)]};
GraphicsRow[plot]

enter image description here

Improve this answer
$\endgroup$
1
  • $\begingroup$ +1. A good code is a commented code. $\endgroup$
    – user64494
    Commented Dec 1, 2023 at 15:37
4
$\begingroup$

First plot:

ComplexRegionPlot[Abs[z - 2] <= 1, {z, 0 - 2 I, 4 + 2 I}]

enter image description here

After transformation:

transformed = Abs[z - 2] <= 1 /. First@Solve[w == z/(z - 1), z]
ComplexRegionPlot[transformed, {w, 0 - 2 I, 4 + 2 I}]

enter image description here

Improve this answer
$\endgroup$
2
$\begingroup$

With z= x+ y I and w:

w[x_, y_] = (x + y I)/(x + y I - 1);

we can vary x from 1 to 3. And y from -Sqrt[1 - (x - 2)^2] to Sqrt[1 - (x - 2)^2], we can plot the image of the circle:

ParametricPlot[
 ReIm[w[x, y]], {x, 1, 3}, {y, -Sqrt[1 - (x - 2)^2], 
  Sqrt[1 - (x - 2)^2]}, PlotRange -> {{0, 3}, {-1.5, 1.5}}]

enter image description here

Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.