Visualising a Riemann surface

Question

I need to solve the equation

z1^n + z2^n == 1

with the parametrisation

z1 = Exp[2 π k1] I Cos[θ - ξ]^(2/n)
z2 = Exp[2 π k1] I Sin[θ - ξ]^(2/n)

Under the following assumptions:

k1, k2 ∈ N
k1 >= 0
k2 <= n − 1
0 <= θ <= π/2
Abs[ξ] <= max ξ 
n = 2

The end result would look something like this and the coordinates {x, y, z} would end up as {Re[z1], Im[z1], Re[z2]}

As I have understood this has something to do with the Riemann sphere.

Answer 1

By reverse engineering: With $z_1 = x + \operatorname{i} y$ and $z_1 = z + \operatorname{i} w$, $x$, $y$, $z$, $w \in \mathbb{R}$, the equation $\Im(z_1^2 + z_2^2) = 0$ leads to an one real equation for w, at least in the case $n=2$. Substituting the solution w of this equation into $\Re(z_1^2 + z_2^2) = 1$ leads to a real equation in $\mathbb{R}^3$. Its solution set can be plotted like this.

z1 = x + I y;
z2 = z + I w;
n = 2;
eq = ComplexExpand[ReIm[z1^n + z2^n] - {1, 0}];
wsol = Solve[eq[[2]] == 0, w, Reals];
eq3D = Expand[z^2 eq[[1]] /. wsol[[1]]];
R = 5;
ContourPlot3D[eq3D == 0, {x, -R, R}, {y, -R, R}, {z, -R, R},
 RegionFunction -> Function[{x, y, z}, x^2 + y^2 + z^2 <= 25],
 PlotPoints -> 60,
 Mesh -> 25
 ]