I want to plot the solution with different values of S, How is it?

Question

I was solving an ordinary non-linear differential equation of the fourth order in the picture attached

to the following code:

S=1,4,7,10; M = 1; a= .4;
solution = 
 NDSolve[{D[F[t],t,t,t,t] == (a/(1+a))*S*(t*F[t]+3*D[F[t],t,t]+D[F[t],t]*D[F[t],t,t]+F[t]*D[F[t],t,t,t])+(a/(1+a))*(M^2)*D[F[t],t,t], 
   F[0] == 0, (D[F[t],t,t] /. t -> 0) == 0, 
   F[1] == 1, (D[F[t],t,t] /. t -> 1) == 0}, F, {t,0,1}]
Plot[Evaluate[First[F[t] /. solution]], {t,0,1}]

I want to plot the solution with different values of S, How is it?

Answer 1

It seems that we need to check the original equation. Here we check the values {S, {1, 4, 7, 10, 0, -1, -4, -7, -9, -12}}

Clear[M, γ, sol];
M = 1; γ = .4;
sol[S_] := 
  NDSolve[{(1 + 1/γ) F''''[η] - 
      S (η*F[η] + 3*F''[η] + F'[η]*F''[η] - 
         F[η]*F'''[η]) - M^2*F''[η] == 0, F[0] == 0, 
    F''[0] == 0, F[1] == 1, F''[1] == 0}, F, {η, 0, 1}];
Plot[Table[
   F[η] /. 
    First@sol[S], {S, {1, 4, 7, 10, 0, -1, -4, -7, -9, -12}}] // 
  Evaluate, {η, 0, 1}, AspectRatio -> 1/GoldenRatio]

Answer 2

Similar to Nasser's fast answer try

M = 1; a = .4;
solution = 
 ParametricNDSolveValue[{ 
   F''''[t] == (a/(1 + a))*
      S*(t*F[t] + 3* F''[t] + F'[t] * F''[t] + 
        F[t]* F'''[t] ) + (a/(1 + a))*(M^2)* F''[t] , F[0] == 0, 
   F''[0] == 0, F[1] == 1, F''[1] == 0}, F, {t, 0, 2}, S]

Plot[Evaluate@ Map[solution[#][t] &, {1, 4, 7, 10}] , {t, 0, 2},PlotLegends -> {1, 4, 7, 10}]

Solutions differ only for t>>1

Answer 3

I want to plot the solution with different values of S

One way is to use ParametricNDSolveValue

ClearAll["Global`*"];
m=1;a=4/10;
ode=D[F[t],t,t,t,t]==(a/(1+a))*s*(t*F[t]+3*D[F[t],t,t]+D[F[t],t]*D[F[t],t,t]+F[t]*D[F[t],t,t,t])+(a/(1+a))*(m^2)*D[F[t],t,t]
ic={F[0]==0,(D[F[t],t,t]/. t->0)==0,F[1]==1,(D[F[t],t,t]/. t->1)==0};
pfun=ParametricNDSolveValue[{ode,ic},F,{t,0,1},{s}];
Plot[(pfun[1])[t],{t,0,1},PlotLabel->"solutioin for s=1"]

Another option is to use Manipulate and make slider for s.