NetGraph won't accept EmbeddingLayers of different n

Question

Why doesn't this work:

NetGraph[{PartLayer[{1}], PartLayer[{2}],
EmbeddingLayer[50, "Input" -> NetEncoder[{"Class", {"male", "female"}}]],
EmbeddingLayer[50, "Input" -> NetEncoder[{"Class", {"child", "adult", "senior"}}]],
CatenateLayer[]}, {1 -> 3 -> 5, 2 -> 4 -> 5}]

NetGraph::tyfail2: Inferred inconsistent dimensions for array "Weights" of third layer (a 2*50 matrix of real numbers versus a 3*50 matrix of real numbers).

But this does:

NetGraph[{PartLayer[{1}], PartLayer[{2}],
EmbeddingLayer[50, "Input" -> NetEncoder[{"Class", {"male", "female", "placeholder"}}]],
EmbeddingLayer[50, "Input" -> NetEncoder[{"Class", {"child", "adult", "senior"}}]],
CatenateLayer[]}, {1 -> 3 -> 5, 2 -> 4 -> 5}]

Obviously, I'm misunderstanding something very basic, but I can't figure out what it is.

Answer 1

Each element in a vector used in a neural network must be of the same type.

In the NetGraph of your first example, your first EmbeddingLayer takes in input of type Restricted["Integer",2] (an integer from 1 to 2, since there are 2 classes), whereas the second one takes an input of type Restricted["Integer",3].

Because of this, the input of your NetGraph is required to be a vector whose elements are simultaneously Restricted["Integer",2] and Restricted["Integer",3], and that's not allowed.

A workaround for this, already mentioned in the comments by Domen, is to have 2 separate inputs for your NetGraph, each of a different type.

NetGraph[{EmbeddingLayer[50, "Input" -> NetEncoder[{"Class", {"male", "female"}}]], EmbeddingLayer[50, "Input" -> NetEncoder[{"Class", {"child", "adult", "senior"}}]], CatenateLayer[]}, {NetPort["Input1"] -> 1 -> 3, NetPort["Input2"] -> 2 -> 3}]