2-dimensional scatter plot of a 3d dataset [duplicate]

Question

I am fairly new to mathematica, I have been trying to find some inbuilt plotting function that lets us plot a scatter plot of a dataset: (x,y,f(x,y)), where color of the plot is based on value of f(x,y); something like matplotlib.pyplot.scatter; for example if I have a dataset: data= {{1,2,3},{4,5,6},...,{1001,1002,1003}}; and I would like to make a plot like in ListPlot and color the data based on #[[3]]&/@ data; Thanks in advance.

Answer 1

Clear["Global`*"]

SeedRandom[1234];

data = {#[[1]], #[[2]], #[[1]]^2 + #[[2]]/2} & /@
   RandomReal[5, {100, 2}];

funcRange = MinMax[data[[All, 3]]];

Legended[
 Graphics[{
   AbsolutePointSize[4],
   {ColorData["Rainbow"][
       Rescale[#[[3]], funcRange]],
      Point[Most@#]} & /@ data},
  Frame -> True,
  FrameLabel -> (Style[#, 14] & /@ {x, y})],
 BarLegend[{"Rainbow", funcRange},
  LegendLabel -> Style["f", 14]]]

Answer 2

t = Partition[Range[1, 1003], 3];

ListPointPlot3D[t, ColorFunction -> (ColorData["Rainbow"][#3] &)]

---

EDIT-1

The closest visualization I can think of for 2D is a ListContourPlot, otherwise it will be a grid of points with different colors.

ListContourPlot[
 Table[Sin[x] Cos[y], {x, 0, 2 \[Pi], \[Pi]/50}, {y, 0, 
   2 \[Pi], \[Pi]/50}], ColorFunction -> "Rainbow"]

---

EDIT-2

t4 = Array[(Sin[(2 \[Pi] #1)/100] Cos[(2 \[Pi] #2)/100]) &, {100, 
    100}] // N

ArrayPlot[t4, ColorFunction -> "Rainbow", Frame -> True, 
 FrameTicks -> Automatic]

---

EDIT-3

Using ListPlot and creating a mock example conforming to a Binormal distribution.

PDF[BinormalDistribution[{50, 50}, {20, 20}, 0], {x, y}]

$$\frac{\exp \left(\frac{1}{2} \left(-\frac{1}{400} (x-50)^2-\frac{1}{400} (y-50)^2\right)\right)}{800 \pi }$$

Define a function and generate dataxy randomly.

fz[{x_, y_}] := 
  PDF[BinormalDistribution[{50, 50}, {20, 20}, 0], {x, y}];

dataxy = RandomVariate[BinormalDistribution[{50, 50}, {20, 20}, 0], 
   1000];

dataz = Rescale[fz[#] & /@ dataxy];

Generate the list of 3-tuples:

alist = MapThread[Flatten[Join[{#1, #2}]] &, {dataxy, dataz}];

Before we color the points, let's see what these look like:

ListPlot3D[alist]

Give each point a color based on #[[3]]

ListPlot[Style[#[[{1, 2}]], Hue@#[[3]]] & /@ alist
 , PlotStyle -> PointSize[0.007], 
 PlotLegends -> BarLegend[{Hue, {0, 1}}]]

I have benefitted from this answer by @becko for the final part.