Shading regions of a contour plot with values above/below a certain value

Question

I have the following contour plot

Mpl = 1.22*10^(19)
Tplot = ContourPlot[Log10[0.5 1/(100)^(1/8) Sqrt[Mpl 10^x] (y)^(6/8)Exp[-(y)^3 1/8]], 
{x, -6, 16}, {y, 1, 10}, PlotLegends -> Automatic, FrameLabel -> {"x", "y"}]

I would like to shade the regions of contours corresponding to values (for simplicity) > 10 and < -10. (The idea is that those regions are not allowed). I feel like there should be an easy way of doing this. The idea is as below

Answer 1

Mathematica 12.1 has HatchFilling :

Mpl = 1.22*10^(19)
ContourPlot[
 Log10[0.5 1/(100)^(1/8) Sqrt[
    Mpl 10^x] (y)^(6/8) Exp[-(y)^3 1/8]], {x, -6, 16}, {y, 1, 10}
 , PlotLegends -> Automatic
 , FrameLabel -> {"x", "y"}
 , ClippingStyle -> {HatchFilling[]}
 , PlotRange -> {Automatic, Automatic, {-10, 10}}]  

It can be superposed with the original plot :

 Mpl = 1.22*10^(19)
 Show[ContourPlot[
  Log10[0.5 1/(100)^(1/8) Sqrt[
     Mpl 10^x] (y)^(6/8) Exp[-(y)^3 1/8]], {x, -6, 16}, {y, 1, 10}, 
  FrameLabel -> {"x", "y"}, PlotLegends -> Automatic], 
 ContourPlot[
  Log10[0.5 1/(100)^(1/8) Sqrt[
     Mpl 10^x] (y)^(6/8) Exp[-(y)^3 1/8]], {x, -6, 16}, {y, 1, 10}(*,
  PlotLegends\[Rule]Automatic*),(*FrameLabel\[Rule]{"x","y"},*)
  ClippingStyle -> {HatchFilling[]}, 
  PlotRange -> {Automatic, Automatic, {-10, 10}}, 
  RegionFunction -> Function[{x, y, z}, z < -10 || z > 10]]]