Calculating the sum of the lengths and plotting all curves on the same map

Question

I have a curve like below;

ParametricPlot[
 FromPolarCoordinates[{Exp[(t + 0)*0.5], t}] // Evaluate, {t, 0, 
  Pi - 0}, PlotRange -> All]

This curve rotates around z axis. Therefore for a rotation of pi/2 gives something like this:

ParametricPlot[
 FromPolarCoordinates[{Exp[(t + Pi/2)*0.5], t}] // 
  Evaluate, {t, -Pi/2, Pi - Pi/2}, PlotRange -> All]

What I want is to plot all the curves in a specified circle when it rotates with 3.6 degrees. And I want the sum of curves in the circle.

I tried this code but it didn't work:

ParametricPlot[Sum[HeavisideTheta[1 -
      ((Exp[(t + Pi*i/50)*0.5]*Cos[t] - 
           1)^2 + (Exp[(t + Pi*i/50)*0.5]*Sin[t])^2)]*
    FromPolarCoordinates[{Exp[(t + Pi*i/50)*0.5], t}], {i, 1, 100}] //
   Evaluate, {t, -Pi*i/50, Pi - Pi*i/50}, PlotRange -> All]

I also tried this code:

ParametricPlot[ Evaluate@Sum[ HeavisideTheta[ 1 - ((Exp[(t + Pi*i/50)*0.5]Cos[t] - 1)^2 + (Exp[(t + Pii/50)*0.5]Sin[t])^2)] FromPolarCoordinates[{Exp[(t + Pi*i/50)*0.5], t}], {i, 1, 100}], {t, -Pi, Pi}, PlotRange -> All]

But it gives something like below:

What I need is something like this:

And the sum of those curves in the circle area.

How should I write the code to achieve what I want?

Answer 1

ctr = {3, 0};
radius = 3;
pp = PolarPlot[Evaluate@Table[Exp[(t + Pi*i/50)*0.5], {i, 1, 100}], {t, -Pi, Pi}, 
 RegionFunction -> (Norm[{#, #2} - ctr] <= radius &)]

Total[ArcLength /@ Cases[pp, _Line, All]]
(* or Total[RegionMeasure /@ Cases[pp, _Line, All]] *)

314.511

If ypu have to use ParametricPlot, you can do

pp2  = ParametricPlot[Evaluate[Table[E^(((j*Pi)/50 + t)/2) { Cos[t], Sin[t]}, {j, 1, 100}]], 
 {t, -Pi, Pi}, 
 RegionFunction -> (Norm[{#, #2} - ctr] <= radius &), PlotRange -> All]

 Total[ArcLength /@ Cases[pp2, _Line, All]]

314.511