2
$\begingroup$

I am looking for an asymptotic expansion for large $x$ for the following integral: $$\int_{0}^{1} \frac{t^{ia}(1-t/2)^{-ia}}{\sqrt{1-t}} e^{ixt} dt$$ $a$ and $x$ are real and positive. I tried using AsymptoticIntegrate but it just throws me the same expression back. Perhaps some clever series expansion could help? I have the first term from this expansion from a question here: https://math.stackexchange.com/questions/3876832/asymptotics-for-2-humbert-series-special-forms I am looking for more terms in order to approximate this function well for large enough $x$.

$\endgroup$
1
  • $\begingroup$ This is rather math than Mathematica. That book by M.Fedoryuk (only in Russian) may be useful to you. $\endgroup$
    – user64494
    Feb 7, 2021 at 5:08

1 Answer 1

5
$\begingroup$

Try this:

ClearAll["`*"]; Remove["`*"];(*Clear All*)

INV = InverseLaplaceTransform[(E^(I t x) (Z - t/2)^(-I a) t^(I a))/Sqrt[1 - t], Z, s](*Where Z=1*)
INT = Integrate[INV, {t, 0, 1}, Assumptions -> {s > 0, a > 0, x > 0}] // FunctionExpand
SER = Series[INT, {x, Infinity, 2}, Assumptions -> {x > 0, s > 0}] // Normal // Expand(*Terms = 2 *)
f[x_, a_] = Limit[LaplaceTransform[SER, s, Z], Z -> 1, Assumptions -> {x > 0, a > 0}] // FunctionExpand // FullSimplify // Expand

$$\frac{1}{2} a^2 e^{-\frac{\pi a}{2}} x^{-2-i a} \Gamma (i a+1)-\frac{(1-i) \sqrt{\pi } 2^{-\frac{1}{2}+i a} a e^{i x}}{x^{3/2}}-i a e^{-\frac{\pi a}{2}} x^{-2-i a} \Gamma (i a+1)-\frac{1}{2} e^{-\frac{\pi a}{2}} x^{-2-i a} \Gamma (i a+1)+i e^{-\frac{\pi a}{2}} x^{-1-i a} \Gamma (i a+1)+\frac{(1-i) \sqrt{\pi } 2^{-\frac{1}{2}+i a} e^{i x}}{\sqrt{x}}$$

Check:

g[x_, a_] := NIntegrate[(t^(I a) (1 - t/2)^(-I a))/Sqrt[1 - t] Exp[I x t], {t, 0,1}, Method -> "LocalAdaptive"];
g[20000, 10] (*For: x=20000 and a=10*)
(*0.0110877 + 0.00582967 I*)
f[20000, 10] // N (*For: x=20000 and a=10*)
(*0.0110877 + 0.00582966 I*)
$\endgroup$
2
  • $\begingroup$ The answer from the Maxim's comment in math.stackexchange.com/questions/3876832/… is h[x_, a_] = -Sqrt[Pi]*Exp[3*Pi*I/4]*2^(I*a) Exp[I*x]/Sqrt[x] and h[20000, 10] // N results in 0.0110933 + 0.00583258 I. Is the game worth the candle? $\endgroup$
    – user64494
    Feb 7, 2021 at 12:05
  • 2
    $\begingroup$ @user64494. Yes, because now I have 2 candles, yours and Maxim's. $\endgroup$ Feb 7, 2021 at 12:14

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.