How to put markers and figure curves in the same color

Question

I have the following code:

Show[LogLinearPlot[fpN, {t, 0.01, 10000}], 
 LogLinearPlot[fpS, {t, 0.01, 10000}], 
 ListLogLinearPlot[Table[dataa[[i]], {i, 1, 8}], 
  PlotMarkers -> {Automatic, 13}, AspectRatio -> 1 , 
  PlotLegends -> 
   Placed[{87, 85, 80, 75, 70, 65, 60, 55}, {0.14, 0.66}]], 
 Frame -> True, PlotRange -> All, Axes -> False, AspectRatio -> 1, 
 FrameStyle -> Directive[Black, 13], 
 FrameLabel -> {Style["x axis", 16], 
   Style["y axis", 16]}]

which gives me the following Figure:

How can I put the markers and the curve figures of the same color in this code?. As an example in the figure the 55 data is a yellow rhombus but the line is red. The data at 60 is a blue square but its line is green. Similar for the other data.

Edit: Just for clarification purposes fpN plots the data from 87 to 75, fpS plots the data from 70 to 55 abd dataa[[i]] contains the data that I am plotting as markers

Thank you?

Answer 1

EDIT:

I added in PlotStyle -> ColorData[97] to the final ListLogLinearPlot. As BrettChampion mentioned, this will prevent issues if the default colour scheme ever changes. Also, I would generally recommend the first set of code if it works as it's a bit cleaner, but the second set of code should work if the first doesn't because fpN and fpS contain something unusual.

Original:

Depending on how exactly fpN and fpS are arranged, you could try:

Show[
  LogLinearPlot[
    fpN~Join~fpS, 
    {t, 0.01, 10000}
  ],
  ListLogLinearPlot[
    Table[dataa[[i]], {i, 1, 8}], 
    PlotMarkers -> {Automatic, 13}, 
    AspectRatio -> 1 , 
    PlotLegends -> Placed[{87, 85, 80, 75, 70, 65, 60, 55}, {0.14, 0.66}]
  ], 
  Frame -> True, PlotRange -> All, Axes -> False, AspectRatio -> 1, 
  FrameStyle -> Directive[Black, 13], 
  FrameLabel -> {Style["x axis", 16], Style["y axis", 16]}
]

which would join the two datasets and allow the automatic colouring to resolve the individual colours. You could also specify the colours directly:

Show[
  LogLinearPlot[
    fpN, 
    {t, 0.01, 10000},
    PlotStyle -> ColorData[97]/@{1, 2, 3, 4}
  ],
  LogLinearPlot[
    fpS,
    {t, 0.01, 10000},
    PlotStyle -> ColorData[97]/@{5, 6, 7, 8}
  ],
  ListLogLinearPlot[
    Table[dataa[[i]], {i, 1, 8}], 
    PlotMarkers -> {Automatic, 13}, 
    AspectRatio -> 1 , 
    PlotStyle -> ColorData[97],
    PlotLegends -> Placed[{87, 85, 80, 75, 70, 65, 60, 55}, {0.14, 0.66}]
  ], 
  Frame -> True, PlotRange -> All, Axes -> False, AspectRatio -> 1, 
  FrameStyle -> Directive[Black, 13], 
  FrameLabel -> {Style["x axis", 16], Style["y axis", 16]}
]

where ColorData[97] is the default Mathematica colouring scheme. There's over 100 built-in swatch colour schemes, and you can also make up lists of your own colours if you'd like more control over the colouring.