Different style for vertical and horizontal lines in ListStepPlot

Question

I would like to color the horizontal portions (the data) of a ListStepPlot in one style (e.g., blue) and the vertical (linking lines) in a different style (e.g., red) in a plot such as this:

d = Table[RandomReal[], 16]; (* or some other computed list *)

ListStepPlot[d, Center]

Neither Mesh nor ClippingStyle nor Exclusions are appropriate, as you can test yourself.

The option Joined-> False eliminates the vertical segments, but I want them to remain. I can kludge such a graph by plotting two: One in red with Joined->True overlapped by another in blue with Joined->False but this is very inelegant.

I need to apply this to ListStepPlot (for a number of reasons), so alternate kludges will not suffice.

Answer 1

Post-processing to re-color horizontal and vertical segments of Line primitives:

ClearAll[postProcess]
postProcess[lsp_, cols_: {Red}] := Module[{cls = cols}, 
   Replace[lsp, {a___, d_Directive, Line[x_]} :> 
     Module[{p = Partition[x, 2, 1], d2 = d /. _?ColorQ -> Last[cls = RotateLeft[cls]]}, 
      {a, d, Line[p[[;; ;; 2]]], d2, Line[p[[2 ;; ;; 2]]]}], All]];

Examples:

SeedRandom[1]
d = Table[RandomReal[], 16];

postProcess[ListStepPlot[d, Center]]

postProcess[ListStepPlot[{d, 1 + d}, Center]]

postProcess[ListStepPlot[{d, 1 + d}, Center], {Directive[Dashed, Purple], Blue}]

postProcess[#, {Dotted, Dashed}] & @
 ListStepPlot[{d, d + 1}, Center, PlotStyle -> 63]

You can use the function postProcess in two ways:

1. wrap ListStepPlot with postProcess as in the examples above, or
2. use it as the option value for the option DisplayFunction.

postProcess[#, {Directive[Dotted, Purple], Directive[Dashed, Cyan]}] & @ 
  ListStepPlot[{d, d + 1}, Center]

ListStepPlot[{d, d + 1}, Center, 
 DisplayFunction -> 
   (postProcess[#, {Directive[Dotted, Purple],   Directive[Dashed, Cyan]}] &)]

Answer 2

May be

z0 = RandomReal[];
d = Table[z = RandomReal[];
   o = {
     {Blue, Line[{{i - 1, z0}, {i, z0}}]},
     {Red, Line[{{i, z0}, {i, z}}]}
     };
   z0 = z;
   o,
   {i, 16}];

Graphics[d, AspectRatio -> 1, ImageSize -> 300, Axes -> True]