Why is this Mandelbrot set's implementation infeasible: takes a massive amount of time to do?

Question

The Mandelbrot set is defined by complex numbers such as $z=z^2+c$ where $z_0=0$ for the initial point and $c\in\mathbb C$. The numbers grow very fast in the iteration.

z = 0; n = 0; l = {0};
While[n < 9, c = 1 + I; l = Join[l, {z}]; z = z^2 + c; n++];l

If n is very large, the numbers become too large and impossible to calculate in practical time limits. I don't know what it would look after long time but doubting whether it would look like here.

What is wrong with this implementation? Why does it take so long time to calculate?

Answer 1

What is wrong: a) you're using exact arithmetic. b) You keep iterating even if the point seems to be escaping.

Try this

ClearAll@prodOrb;
prodOrb[c_, maxIters_: 100, escapeRadius_: 1] := 
 NestWhileList[#^2 + c &,
  0.,
  Abs[#] < escapeRadius &,
  1,
  maxIters
  ]

prodOrb[0. + 10. I]
prodOrb[0. + .1 I]

(if you don't need the entire list but only the final point, replace NestWhileList by NestWhile).

Here, I use approximate numbers by using 0. rather than 0. See this tutorial for more.

EDIT: Since we're doing interactive manipulation:

ClearAll[mnd];
mnd = Compile[{{maxiter, _Integer}, {zinit, _Complex}, {dt, _Real}},
   Module[{z, c, iters},
    Table[
     z = zinit;
     c = cr + I*ci;
     iters = 0.;
     While[(iters < maxiter) && (Abs@z < 2),
      iters++;
      z = z^2 + c
      ];
     Sqrt[iters/maxiter],
     {cr, -2, 2, dt}, {ci, -2, 2, dt}
     ]
    ],
   CompilationTarget -> "C",
   RuntimeOptions -> "Speed"
   ];


Manipulate[
 lst = mnd[100, {1., 1.*I}.p/500, .01];
 ArrayPlot[Abs@lst],
 {{p, {250, 250}}, Locator}
 ]

Clicking around changes the fractal. Note the magic numbers sprinkled throughout the code. Why? Because ListContourPlot is way too slow, so that using the coords of the clicked point ended up being too much of a waste of time (and my coffee break is over).

EDIT2: So much for the break being over. Here we have the Mandelbrot set being blown away by strong winds:

tbl = Table[
  lst = mnd[100, (1 + 1.*I)*p/500, .01];
  ArrayPlot[Abs@lst],
  {p, 0, 500, 10}
  ];

ListAnimate[tbl]

And see, here it is, sliding off the table while being melted:

tbl2 = Table[
   mnd[100, (1 + 1.*I)*p/500, .05] // Abs // 
    ListPlot3D[#, PlotRange -> {0, 1}, 
      ColorFunction -> "BlueGreenYellow", Axes -> False, 
      Boxed -> False, 
      ViewVertical -> {0, (p/500), Sqrt[1 - (p/500)^2]}] &,
   {p, 0, 500, 25}
   ];

(this is very slow, because ListPlot3D is very slow)

Maximal silliness has now been achieved. Or has it?

Answer 2

Just a bit of fun with @acl's code:

ArrayPlot[Table[
  NestWhile[#^2 - (0. - 1 I) & , r + i I, Abs[#] < 2.0 &, 1, 10],
  {r, -2, 2, 0.005},
  {i, -2, 2, 0.005}]]

Answer 3

With a compiled version you get it so fast, that you can manipulate it in real time.

fc = Compile[{{in, _Complex, 0}, {c, _Complex, 0}},
   Module[{iter = 0, max = 10, z = in},
    While[iter++ < max,
     If[Abs[z = z^2 + c] > 2.0,
      Break[]
      ]
     ];
    {Abs[z], iter}
    ], CompilationTarget -> "C", Parallelization -> True, 
   RuntimeAttributes -> {Listable}
   ];

data = Table[i + I j, {j, -2, 2, .01}, {i, -2, 2, .01}];

Manipulate[ImageAdjust[Image[fc[data, cx + I cy]]],
 {cx, -.5, .5},
 {cy, -.5, .5}
]

And since my iteration does calculate a Julia set instead of the Mandelbrot set, let's fix this

fc = Compile[{{c, _Complex, 0}},
   Module[{iter = 0, max = 100, z = 0 + 0 I},
    While[iter++ < max,
     If[Abs[z = z^2 + c] > 2.0,
      Break[]
      ]
     ];
    {Log[iter], Abs[z]}
    ], CompilationTarget -> "C", Parallelization -> True, 
   RuntimeAttributes -> {Listable}
   ];

data = Table[i + I j, {j, -2, 2, 4/1023.}, {i, -2, 2, 4/1023.}];
ImageAdjust[Image[fc[data]]]

To calculate this 1024x1024 image, it took only 0.2 seconds on my machine here. I wouldn't consider this slow.

Answer 4

As @acl mentioned in chat, your question really indicates that you should read some fundamental sources. Two that I'd recommend are:

• A First Course in Chaotic Dynamical Systems by Bob Devaney for a good overview of the mathematical theory.
• Mathematica in Action by Stan Wagon, specifically Chapter 11, for a more condensed overview but with specific Mathematica code.

Note that the second reference, which I happen to have written largely avoids Compile and the speediest of speedy tricks presented by the other answers here in favor of simpler code. This is probably better, if your objective is to learn the basics of the material.

Answer 5

In Mathematica 10.0:

    MandelbrotSetPlot[{-2 - I, 1 + I}]

(Admittedly, this doesn't address what's wrong with the code in the original question, but if you just want to get a Mandelbrot set plot, surely a built-in function is likely to be reasonably efficient.)

Answer 6

ClearAll[mandel];
mandel =
  Compile[{{A, _Real, 1}, {maxIt, _Real}},
   Module[{i = 0, re = 0., im = 0., temp, x = A[[1]], y = A[[2]]},
    While[i++ < maxIt && re^2 + im^2 <= 4,
     temp = re^2 - im^2 + x;
     im = 2 re im + y;
     re = temp;
     ];
    {Log[i], Sqrt[re^2 + im^2]}
    ],
    CompilationTarget -> "C", RuntimeOptions -> "Speed", RuntimeAttributes -> {Listable}
   ];

t1 = AbsoluteTime[];
data = mandel[Table[{i, j}, {j, -2, 2, 4/1023.}, {i, -2, 2, 4/1023.}], 100];
Image@Rescale@data
AbsoluteTime[] - t1