Finding the global maximum of a function

Question

I've the following code:

R = 1;
L = 100;
c = 5;
\[Omega] = 1;
Uin = 1;
Plot[InverseLaplaceTransform[((Uin*\[Omega])/(s^2 + \
\[Omega]^2))*(R/(c*L*R*s^2 + L*s + R)), s, t], {t, 0, 
  10*((2 Pi)/\[Omega])}]

The output gives:

How can I find the global maximum of that function? So I need to find the time $t$ where the function on the y-axis is the biggest. I can see it is roundabout $t=17$ but how can I use Mathematica to solve for that point?

Answer 1

Clear["Global`*"]

R = 1;
L = 100;
c = 5;
ω = 1;
Uin = 1;

f[t_] = InverseLaplaceTransform[((Uin*ω)/(s^2 + ω^2))*(R/(c*L*R*
         s^2 + L*s + R)), s, t] // FullSimplify

(* (1/259001)(-100 Cos[t] - 499 Sin[t] + 
  5 E^(-t/10) (20 Cosh[t/(5 Sqrt[5])] + 509 Sqrt[5] Sinh[t/(5 Sqrt[5])])) *)

Plot the function to adaptively sample it

plt = Plot[f[t], {t, 0, 10*((2 Pi)/ω)}]

The points in the function are

data = Cases[plt, Line[pts_] :> pts, Infinity][[1]];

The peak data point is

peak = data[[SortBy[FindPeaks[data[[All, 2]]], Last][[-1, 1]]]]

(* {17.0672, 0.0108751} *)

Using this as an initial estimate, the function's maximum is then

FindMaximum[f[t], {t, peak[[1]]}, WorkingPrecision -> 20]

(* {0.010875072207704462201, {t -> 17.071813673825464498}} *)

or

Maximize[{f[t], 19/20 peak[[1]] < t < 21/20 peak[[1]]}, t, 
 WorkingPrecision -> 20]

(* {0.0108751, {t -> 17.0718}} *)

Answer 2

With additional information, that second derivative is negative (which NMaximize should know anyway), you get the right result.

Edit: I think, this works, because second derivative reproduces the Sin and Cos term with same but negative prefactor, so that NMaximize can eliminate these terms.

NMaximize[{f[t], D[f[t], {t, 2}] < 0}, t]

(*  {0.0108751, {t -> 17.0718}}    *)

Edit2

Even Maximizedoes the job easily if you restrict t a little bit away from zero.

Maximize[{f[t], 10^-6 < t < 100}, t, Reals]

You get a root expression for t which you can use for further analytical calculations.

{t -> Root[{-998 E^(1/50 (-5 + 2    Sqrt[5]) #1) + 
  501 Sqrt[5] E^(1/50 (-5 + 2 Sqrt[5]) #1) - 
  998 E^(-(1/50) (5 + 2 Sqrt[5]) #1) - 
  501 Sqrt[5] E^(-(1/50) (5 + 2 Sqrt[5]) #1) + 1996 Cos[#1] - 
  400 Sin[#1] &, 17.0718136738254647391}]}