Proving the positive semidefiniteness of a 6X6 symbolic matrix

Question

Specifically, I want to check the positive semidefiniteness of the following 6X6 symbolic matrix

{{-2 (-((11 m1^2 - 24 m1 m3 + 72 m3^2)/(
      144 k^2 m1^2 m3^2 \[Sigma]^2)) - 2 \[Sigma]^2), 
  I - (m1 - 6 m3)/(6 k m1 m3 \[Sigma]^2), (
  3/m1 + 1/m3 + (12 \[Sigma]^4)/m2)/(6 k \[Sigma]^2), 2 \[Sigma]^2, 
  1/(8 k^2 m3^2 \[Sigma]^2) + 4 \[Sigma]^2, (m1 + 12 m3)/(
  12 k m1 m3 \[Sigma]^2)}, {-I - (m1 - 6 m3)/(6 k m1 m3 \[Sigma]^2), 
  1/\[Sigma]^2, 1/(2 \[Sigma]^2), 0, 0, 1/\[Sigma]^2}, {(
  3/m1 + 1/m3 + (12 \[Sigma]^4)/m2)/(6 k \[Sigma]^2), 1/(
  2 \[Sigma]^2), 1/\[Sigma]^2 + (4 \[Sigma]^2)/(k^2 m2^2), 
  I + (4 \[Sigma]^2)/(k m2), (1/m3 + (16 \[Sigma]^4)/m2)/(
  4 k \[Sigma]^2), 1/\[Sigma]^2}, {2 \[Sigma]^2, 
  0, -I + (4 \[Sigma]^2)/(k m2), 4 \[Sigma]^2, 4 \[Sigma]^2, 
  0}, {1/(8 k^2 m3^2 \[Sigma]^2) + 4 \[Sigma]^2, 0, (
  1/m3 + (16 \[Sigma]^4)/m2)/(4 k \[Sigma]^2), 4 \[Sigma]^2, 
  1/(8 k^2 m3^2 \[Sigma]^2) + 6 \[Sigma]^2, 
  I + 1/(4 k m3 \[Sigma]^2)}, {(m1 + 12 m3)/(12 k m1 m3 \[Sigma]^2), 
  1/\[Sigma]^2, 1/\[Sigma]^2, 0, -I + 1/(4 k m3 \[Sigma]^2), 3/(
  2 \[Sigma]^2)}}

Which depends on the 5 parameters: $m_{1}$, $m_{2}$, $m_{3}$, $k$, $\sigma$, which are all positive, that is

$m_{1}>0, m_{2}>0, m_{3}>0, k>0, \sigma>0 \tag{1}$ .

I try to apply the methodology proposed in (Checking if a symbolic matrix is positive semi-definite) but Mathematica stays doing the calculation and does not yield a result.

Then, as another way to tackle the problem, I tried to numerically inspect the minimum and maximum values of the eigenvalues of the above matrix, by using NMinimize[] and NMaximize[] subject to the constraints given in (1). My code is

s=Simplify[Eigenvalues[{{-2 (-((11 m1^2-24 m1 m3+72 m3^2)/(144 k^2 m1^2 m3^2 \[Sigma]^2))-2 \[Sigma]^2),I-(m1-6 m3)/(6 k m1 m3 \[Sigma]^2),(3/m1+1/m3+(12 \[Sigma]^4)/m2)/(6 k \[Sigma]^2),2 \[Sigma]^2,1/(8 k^2 m3^2 \[Sigma]^2)+4 \[Sigma]^2,(m1+12 m3)/(12 k m1 m3 \[Sigma]^2)},{-I-(m1-6 m3)/(6 k m1 m3 \[Sigma]^2),1/\[Sigma]^2,1/(2 \[Sigma]^2),0,0,1/\[Sigma]^2},{(3/m1+1/m3+(12 \[Sigma]^4)/m2)/(6 k \[Sigma]^2),1/(2 \[Sigma]^2),1/\[Sigma]^2+(4 \[Sigma]^2)/(k^2 m2^2),I+(4 \[Sigma]^2)/(k m2),(1/m3+(16 \[Sigma]^4)/m2)/(4 k \[Sigma]^2),1/\[Sigma]^2},{2 \[Sigma]^2,0,-I+(4 \[Sigma]^2)/(k m2),4 \[Sigma]^2,4 \[Sigma]^2,0},{1/(8 k^2 m3^2 \[Sigma]^2)+4 \[Sigma]^2,0,(1/m3+(16 \[Sigma]^4)/m2)/(4 k \[Sigma]^2),4 \[Sigma]^2,1/(8 k^2 m3^2 \[Sigma]^2)+6 \[Sigma]^2,I+1/(4 k m3 \[Sigma]^2)},{(m1+12 m3)/(12 k m1 m3 \[Sigma]^2),1/\[Sigma]^2,1/\[Sigma]^2,0,-I+1/(4 k m3 \[Sigma]^2),3/(2 \[Sigma]^2)}}]];
(*The first eigenvalue is 0*)
s[[1]]

(*Maximum and Minimum of second eigenvalue*)
NMinimize[s[[2]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]
NMaximize[s[[2]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]

(*Maximum and Minimum of third eigenvalue*)
NMinimize[s[[3]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]
NMaximize[s[[3]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]

(*Maximum and Minimum of fourth eigenvalue*)
NMinimize[s[[4]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]
NMaximize[s[[4]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]

(*Maximum and Minimum of fifth eigenvalue*)
NMinimize[s[[5]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]
NMaximize[s[[5]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]

(*Maximum and Minimum of sixth eigenvalue*)
NMinimize[s[[6]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]
NMaximize[s[[6]],m1>0&&m2>0&&m3>0&&k>0&&\[Sigma]>0,{m1,m2,m3,m3,k,\[Sigma]}]

Particularly I tried this method due to the following reasoning:

If some eigenvalue becomes purely negative, their maximum and minimum values ​​will also be negative, and, in this situation, the matrix defined above will not be a semidefinite matrix

Then, in my code, I find that the second eigenvalue (s[[2]]) has a negative maximum and minimum, therefore, proving that the matrix has negative eigenvalues and therefore being a non-semidefinite matrix. But the problem is that Mathematica shows the following error at the output of the Max and Min calculation

minimize::cvmit: Failed to converge to the requested accuracy or precision within 100 iterations. >>

Thus, so I have two questions

1. How to remove the aforementioned error?

2. Do you have any other suggestions to prove the positive semidefiniteness of the aforementioned matrix?

Answer 1

Your matrix isn't positive semi-definite for all values of $m1>0, m2>0, m3>0, k>0, σ>0$.

Proof by contradiction...one of the Eigenvalues is negative for the parameter settings below.

mat = (* your matrix *)

Min@Eigenvalues@(mat /. {m1 -> 1, m2 -> 2, m3 -> 3, k -> 4, σ -> 5}) // N
(* -0.0882134  *)

Digging a little deeper for positve semidefiniteness, all of the leading principal minors must be non-negative. Testing for the 5th principal minor (the determinant of the upper left $5 \times 5$ submatrix)

Reduce[{Det@mat[[1 ;; 5, 1 ;; 5]] < 0, 
       m1 > 0, m2 > 0, m3 > 0, k > 0, σ > 0}, 
      {m1, m2, m3, k, σ}]

(* m1 > 0 && m2 > 0 && m3 > 0 && k > 0 && σ > 0 *)

So the 5th principal minor is always less than zero when your parameters are greater than zero.