Suppose I have something like
Manipulate[Plot[Sin[n x], {x, -Pi, Pi}], {n, 20, "Frequency"}]
with a manual input field but I want to accept inputs like 20 Hz. Is there any way of doing that?
$\begingroup$
$\endgroup$
Add a comment
|
1 Answer
$\begingroup$
$\endgroup$
3
Does it fit your needs?
Manipulate[
Plot[Sin[hz x], {x, -Pi, Pi}]
, { {input, "1 Hz", "Frequency"}
, InputField[#, String, ##2] &
, TrackingFunction :> Function[
new
, Catch[
hz = Check[
QuantityMagnitude[Interpreter["Quantity"] @ new, "Hertz"]
, Throw @ $Failed
]
; input = new
]
]
}
, {{hz, 1}, None} (*just for scoping*)
]
-
$\begingroup$ Actually, whoever edited the question screwed up. My original question was about % input, so if you input 20% it should be passed on as 0.2 (so, you want to transform the input in a fixed way). $\endgroup$ Commented Oct 22, 2019 at 16:53
-
$\begingroup$ But looks like the right thing, thanks! $\endgroup$ Commented Oct 22, 2019 at 16:56
-
$\begingroup$ @IgorRivin it was me because it was slightly confusing. If you want we can revert it and add clarification. $\endgroup$– KubaCommented Oct 23, 2019 at 5:27