Expected value of Product of N terms from a Distribution

Question

I don't understand how to calculate

The Expected value of ∏ x(i) for N values of x(i) taken from a uniform distribution.

i.e. to generalise

Expectation[ 
   x * y *z, { x ~ UniformDistribution[], 
               y ~ UniformDistribution[], 
               z ~ UniformDistribution[]
              }]

to N terms. (And no, “½^N” is not the answer I'm looking for.)

Answer 1

Clear["Global`*"]

Using Expectation

exp[n_Integer?Positive] := exp[n] = 
   Expectation[
    Product[x[k], {k, n}],
    Evaluate@
     (x[#] \[Distributed] UniformDistribution[] & /@ Range[n])]

seq = exp /@ Range[10]

(* {1/2, 1/4, 1/8, 1/16, 1/32, 1/64, 1/128, 1/256, 1/512, 1/1024} *)

FindSequenceFunction[seq, n]

(* 2^-n *)

Using TransformedDistribution

dist[n_Integer?Positive] := dist[n] =
  TransformedDistribution[Product[x[k], {k, n}],
   Evaluate@
    (x[#] \[Distributed] UniformDistribution[] & /@ Range[n])]

seq2 = Mean[dist[#]] & /@ Range[10]

(* {1/2, 1/4, 1/8, 1/16, 1/32, 1/64, 1/128, 1/256, 1/512, 1/1024} *)

EDIT: Or, as suggested by @ciao, using the multivariate uniform distribution over the standard n dimensional unit hypercube,

Clear[dist]

dist[n_Integer?Positive] := dist[n] = Module[{var = Array[x, n]},
   TransformedDistribution[
    Times @@ var, var \[Distributed] UniformDistribution[n]]]

seq2 = Mean@*dist /@ Range[10]

(* {1/2, 1/4, 1/8, 1/16, 1/32, 1/64, 1/128, 1/256, 1/512, 1/1024} *)

FindSequenceFunction[seq2, n]

(* 2^-n *)