Trying to Create an Animated Vector Plot of Tangential Velocities

Question

Wanted to see if anyone could help me out here.

I interested in seeing if it's possible to animate this vector plot I've created.

r[x_, y_] := Sqrt[x^2 + y^2];
R2[x_, y_] := r[x, y]^2 + 1 + 2/r[x, y];
phidot[x_, y_] := If[r[x, y] >= 2, 2/((r[x, y])^3 + r[x, y] + 2), 0];
vx[x_, y_] := -y phidot[x, y];
vy[x_, y_] := x phidot[x, y];
VectorPlot[{vx[x, y], vy[x, y]}, {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi],
2 \[Pi]}]

The equation used to create this vector field describes the speed at which space is drug by an extreme Kerr black hole. As you get closer to the event horizon, r = 1, space is drug faster, hence the bigger vectors. If possible, what I'd like to do is to get the vectors to circle around the origin in a similar manner, with some representation of their magnitude, at least relative to each other. If anyone could offer some assistance, I'd really appreciate it.

As a bonus, it would be cool if any different colors or background were possible.

Thanks!

Answer 1

This answer is similar to @Edmund's, except with the rotation angle dependent on the radius:

pts2 = Table[
   Table[{x Sin[t], x Cos[t]}, {t, 0, 2 π, π/(2 x)}], {x, 1, 8}];
a = Table[VectorPlot[{vx[x, y], vy[x, y]}, {x, -2 π, 2 π}, {y, -2 π, 2 π}, 
    VectorPoints -> (Flatten[Table[RotationMatrix[ϕ/x].# & /@ pts2[[x]], {x, 1, 8}], 1])], {ϕ, 0, 2 π, π/20}];

Export["vectors.gif", a]

Edited to include an updated version in which it's easier to adjust the parameters:

numcircles = 20;
circlespacing = .5;
pointspacing = π/4;
frameinterval = π/20;

pts2 = Table[Table[{x Sin[t], x Cos[t]}, {t, 0, 2 π, pointspacing/x}], {x, 1, numcircles, circlespacing}];
a = Table[VectorPlot[{vx[x, y], vy[x, y]}, {x, -numcircles circlespacing, numcircles circlespacing}, {y, -numcircles circlespacing, numcircles circlespacing}, 
    VectorPoints -> (Flatten[
       Table[RotationMatrix[ϕ/n].# & /@ pts2[[n]], {n, Length[pts2]}], 1])], {ϕ, 0, 2 π - frameinterval, frameinterval}];

Answer 2

You may use RotationMatrix with the VectorPoints option.

Using Tuples and Subdivide to get an initial set of VectorPoints.

vpoints = Tuples[ConstantArray[Subdivide[-3 \[Pi], 3 \[Pi], 25], 2]];

Then with Manipulate

Manipulate[
 VectorPlot[{vx[x, y], vy[x, y]}, {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2. \[Pi]},
  VectorPoints -> vpoints . RotationMatrix[r]],
 {{r, 0}, 0, -\[Pi]}
 ]

As VectorPlot mentions in its documentation, it has the same options as Graphics. Look there for options on background colours and more.

Hope this helps.