2
$\begingroup$

I'm brand new to Mathematica and trying to figure it out, my task is to create a chord with labels on each end (currently using a small section of the sine curve).

Currently I've just got

Plot[Sin[x], {x, 1, 1.5}, PlotRange -> {0.75, 1.1},
 PlotStyle -> {Blue}, AxesLabel -> {x, φ}]

I've managed to draw on the points and arrows at either end, but I'm struggling to zoom out on the graph to leave space at either end for my annotations

I'm really new to this and struggling to find a good way to do this, can anyone give me any pointers?

enter image description here

$\endgroup$
3
  • 1
    $\begingroup$ You refer to points and arrows but have not provided the code that would tell us what points and arrows you are drawing nor what labels you want and where. $\endgroup$
    – Bob Hanlon
    Nov 24, 2020 at 19:26
  • $\begingroup$ Apologies, I'm bad at explaining what I need done. I've attached a rough sketch of the graph I'm trying to re-create on Mathematica, hopefully it helps. $\endgroup$ Nov 24, 2020 at 19:37
  • 1
    $\begingroup$ To zoom out, try PlotRange->{ {0.75, 1.75}, {0.75, 1.1} }. That is, specify both the x-axis and the y-axis ranges. $\endgroup$
    – LouisB
    Nov 24, 2020 at 20:06

1 Answer 1

3
$\begingroup$
Clear["Global`*"]

f[x_] = Sin[x];

The tangent line at x0

t[x_, x0_] := (x - x0)*f'[x0] + f[x0]

Put the annotations in an Epilog

Plot[Sin[x], {x, 1, 1.5}, PlotRange -> {{0.8, 1.75}, {0.75, 1.05}},
 Epilog -> {
   Text[Style["A", 14], {1, f[1]}, {-2, 0}],
   Text[Style[Subscript["T", "A"], 14], {.9, t[.9, 1]}, {-2, 0}],
   Text[Style["B", 14], {1.5, f[1.5]}, {0, -1.5}],
   Text[Style[Subscript["T", "B"], 14], {1.7, t[1.7, 1.5]}, {0, -1.5}],
   Text[Style["∡α", 14], {0.94, 0.835}],
   Text[Style["∡β", 14], {1.7, 1.005}],
   ColorData[97][2],
   Arrow[{{1, f[1]}, {.9, t[.9, 1]}}],
   Arrow[{{1.5, f[1.5]}, {1.7, t[1.7, 1.5]}}],
   Dashed, Line[{{.85, f[1]}, {1, f[1]}}],
   Line[{{1.7, f[1.5]}, {1.5, f[1.5]}}],
   Red, AbsolutePointSize[4],
   Point[{#, f[#]} & /@ {1, 1.5}]},
 AspectRatio -> 1.25]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.