0
$\begingroup$
Integrate[Y^(b - 1) (1 - Y)^(a - 1) (-Log [Y])^-k, {Y, 0, 1}, 
          Assumptions -> {0 < a, 0 < b, k != 0}]

Integrate doesn't evaluate and display the same thing as input. I want the output to be a function of $a$,$b$,$k$

$\endgroup$
  • 1
    $\begingroup$ "display the same thing as input" - usually, that means Mathematica doesn't know if your integral has a closed form. $\endgroup$ – J. M.'s discontentment Mar 28 '18 at 5:39
3
$\begingroup$

You get results if a values are element of the integers and k < a.

int[a_, b_, k_, assum___] := 
  Integrate[Y^(b - 1) (1 - Y)^(a - 1) (-Log[Y])^(-k), {Y, 0, 1}, 
    Assumptions -> 
      Join[{a > 0, b > 0, k \[Element] Reals, 
        a \[Element] Integers}, {assum}]]

Do integration for some integer a

Table[int[a, b, k], {a, 1, 5}]

(*   {ConditionalExpression[b^(-1 + k) Gamma[1 - k], k < 1], 
      ConditionalExpression[(b^(-1 + k) - (1 + b)^(-1 + k)) Gamma[1 - k], 
    k < 2], ConditionalExpression[(b^(-1 + k) - 
 2 (1 + b)^(-1 + k) + (2 + b)^(-1 + k)) Gamma[1 - k], k < 3], 
      ConditionalExpression[-(-b^(-1 + k) + 3 (1 + b)^(-1 + k) - 
  3 (2 + b)^(-1 + k) + (3 + b)^(-1 + k)) Gamma[1 - k], k < 4], 
      ConditionalExpression[(b^(-1 + k) - 4 (1 + b)^(-1 + k) + 
 6 (2 + b)^(-1 + k) - 
 4 (3 + b)^(-1 + k) + (4 + b)^(-1 + k)) Gamma[1 - k], k < 5]}   *)

you get integrals for k < a. Analysing the results gives the rule

s[a_] := Sum[(-1)^i Binomial[(a - 1), i] (i + b)^(-1 + k), {i, 0, 
              a - 1}]*Gamma[1 - k]

Proof this rule

Table[int[a, b, k, k < a] == s[a], {a, 1, 5}] // Simplify // TableForm

(*   True, True, True, True,True }

Now define the solution with k < a

int1[a_?IntegerQ, b_, k_] := 
  Sum[(-1)^i Binomial[(a - 1), i] (i + b)^(-1 + k), {i, 0, a - 1}]*
    Gamma[1 - k]

For integer k you have to take the limit for example Limit[int1[14, 11, k], k -> 2]

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.