2
$\begingroup$

I am trying to solve the following integral having two strictly positive parameters:

Integrate[(u - 1)^2 * (1 - u^(-1/xi))^(k - 3) * u^(-3/xi - 3), 
 {u, 1, Infinity}, Assumptions -> {xi > 0, k > 0}]

but the returned solution only holds for $k > 2$.

If I integrate the same expression by making separate assumptions on $k$ (that is, first I integrate assuming $k > 2$, then I integrate assuming $k = 2$ and so on ...), I am able to get a solution for $k=1$, $k=2$ and $k>2$. But when I run

Integrate[(u - 1)^2 * (1 - u^(-1/xi))^(k - 3) * u^(-3/xi - 3), 
 {u, 1, Infinity}, Assumptions -> {xi > 0, 0 < k < 1}]

Mathematica returns the same unevaluated expression. The same happens when I integrate the expression assuming $1<k<2$.

Additional attempts: I tried to solve the integral by first applying the function FullSimplify but nothing changes. I also developed the term (u - 1)^2 and multiplied each of its element for (1 - u^(-1/xi))^(k - 3) * u^(-3/xi - 3) to find out that the integrals do not converge on {1, Infinity} for 0<k<1 nor for 1<k<2.

How can I solve the integral for $0<k<1$ and $1<k<2$?

$\endgroup$

1 Answer 1

4
$\begingroup$

Let us investigate the behavior of the integrand as $u\to 1$

Series[(u - 1)^2*(1 - u^(-1/xi))^(k - 3)*u^(-3/xi - 3), {u, 1, 2}, 
Assumptions -> {xi > 0, k > 0}] // Normal

(-1 + u)^(-1 + k) xi^(3 - k)

and as $u\to \infty$

Series[(u - 1)^2*(1 - u^(-1/xi))^(k - 3)*u^(-3/xi - 3), {u, Infinity,   2}, 
Assumptions -> {xi > 0, k > 0}] // Normal

u^(-3 - 3/xi) (1 - 2 u + u^2) (1 - u^(-1/xi))^(-3 + k)

The above results prove the convergence of the integral under consideration if xi > 0, k > 0.

In view of it we may consider

j = Integrate[(u - 1)^2*(1 - u^(-1/xi))^(k - 3)*u^(-3/xi - 3), {u, 1,  Infinity},
 Assumptions -> {xi > 0, k > 0},  GenerateConditions -> False]

xi (2/(k (2 - 3 k + k^2)) + Gamma[-2 + k] (-((2 Gamma[3 + xi])/Gamma[1 + k + xi]) + Gamma[3 + 2 xi]/Gamma[1 + k + 2 xi]))

Numeric calculations

N[j /. {k -> 1/2, xi -> 1/10}]

0.00127714

and

NIntegrate[(u - 1)^2*(1 - u^(-1/xi))^(k - 3)* u^(-3/xi - 3) /. {k -> 1/2, xi -> 1/10}, {u, 1, Infinity}]

0.00127714

confirm it.

$\endgroup$
4
  • $\begingroup$ It should be noticed that Limit[j, k -> 1, Assumptions -> xi > 0] produces xi (-((2 Gamma[3 + xi] (-1 + EulerGamma + PolyGamma[0, 2 + xi]))/ Gamma[2 + xi]) + (Gamma[ 3 + 2 xi] (-1 + EulerGamma + PolyGamma[0, 2 + 2 xi]))/ Gamma[2 + 2 xi]). $\endgroup$
    – user64494
    Jun 19, 2023 at 18:45
  • $\begingroup$ What about integer k<2 ? Gamma[] is ComplexInfinity on negative integers, so the Gamma[-2 + k] part would be problematic for integer k<2. I suppose it does not matter too much though since k can take on any other non-integer value $\endgroup$
    – ydd
    Jun 19, 2023 at 19:48
  • $\begingroup$ Thanks @user64494 for your help. If you showed that the integral converges for $xi>0, k>0$, why does Mathematica return the same solution only for $k>2$ when GenerateConditions is put equal to True? In addition, if I need to evaluate j in $k==1$ I can't because of the indeterminate form. Is it correct in this case to use the value returned by Integrate[(u - 1)^2 * (1 - u^(-1/xi))^(k - 3) * u^(-3/xi - 3), {u, 1, Infinity}, Assumptions -> {xi > 0, k == 1}] in order to evaluate the solution in $k==1$? $\endgroup$
    – cpcf
    Jun 19, 2023 at 22:04
  • 1
    $\begingroup$ Try taking limits as k aapraches 1 or 2. It looks like there might be singular terms that cancel. $\endgroup$ Jun 19, 2023 at 22:21

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.