Unable to evaluate the Limit of an expression at Infinity, with assumptions on parameters

Question

I need some help in evaluating the following limit with assumptions:

Limit[Result, L -> Infinity, Assumptions -> A ∈ Integers && A > 0 && 
    B ∈ Integers && B > 0 && C ∈ Integers && C > 0 && D > 0 && F > 0]

where

Result := C D (B F)^(A + L) (-C D + B F)^-A 
     ((C D + B F)^(-1 - L) - ((-C D + B F)^(-1 - L)
     Gamma[1 + A + L] Hypergeometric2F1[1 + L, 1 + A + L, 
     2 + L, -((C D + B F)/(-C D + B F))])/(Gamma[A] Gamma[2 + L]))

It should come out to 0, and I am sure of this. I just need to verify.

The reason is that I plugged in values for all of the parameters (except L), and then summed over Result from L=0 to L=100000 - the sum converges to 1.

Mathematica is unable to evaluate this limit as I defined it. Is there a proper way?

Thanks in advance for any help.

Answer 1

It is convenient to replace C by a B F/D, where a > 0. Also, specify that L is positive.

Simplify[Result /. C -> a B F/D, B > 0 && F > 0 && a > 0 && L > 0]
(* (1 - a)^-A a B F (B F)^L (((1 + a) B F)^(-1 - L) - ((-(-1 + a) B F)^(-1 - L)
   Gamma[1 + A + L] Hypergeometric2F1[1 + L, 1 + A + L, 2 + L, 
   (1 + a)/(-1 + a)])/(Gamma[A] Gamma[2 + L])) *)

It is not uncommon for Limit to fail when dealing with hypergeometric functions. So, use Series instead.

Series[%, {L, Infinity, 1}, Assumptions -> B > 0 && F > 0 && L > 0] // Normal
(* ((1 - a)^-A a (B F)^L ((1 + a) B F)^-L)/(1 + a) *)
FullSimplify[%, B > 0 && F > 0 && L > 0 && a > 0]
(* (1 - a)^-A a (1 + a)^(-1 - L) *)
Limit[%, L -> Infinity, Assumptions -> a > 0]
(* 0 *)

as desired.