5
$\begingroup$

I'm new to Mathematica so I apologize if the answer to my question is trivial. I need to calculate the following integral $$ \int_{-\infty}^{0}\frac{dx}{\sqrt{(x-a)(x-b)(x-c)(x-d)}} $$ with $$ 0 < d < c < b < a $$ (of course $a,b,c$ and $d$ are real)

Is it possible to obtain a results in terms of $a,b,c$ and $d$?

And if it is possible how should I do?

$\endgroup$
0
8
$\begingroup$

This is a kind of elliptic integral, and it can be calculated if we prescribe appropriate assumptions.

Integrate[ 1/Sqrt[(x - a) (x - b) (x - c) (x - d)], {x, -Infinity, 0}, 
           Assumptions -> 0 < d < c < b < a]
-((2(EllipticF[ArcSin[Sqrt[(a - d)/(b - d)]], ((a - c) (b - d))/((b - c) (a - d))]
   - EllipticF[ArcSin[Sqrt[(b (a - d))/(a (b - d))]], 
               ((a - c) (b - d))/((b - c) (a - d))]))/Sqrt[(b - c) (a - d)])

enter image description here

EllipticF is the incomplete elliptic integral of the first kind. Such an integral can be also expressed in terms of the Weierstrass elliptic function, precisely by its inverse.

$\endgroup$
7
$\begingroup$

Artes shows that the integral can be expressed in terms of the Legendre-Jacobi integrals. I will now present a solution that uses the Carlson elliptic integrals, for which I have written a package implementing them.

In particular, our working formulae are a combination of formulae 19.29.4 and 19.29.6 in the DLMF:

<<Carlson` (* load package after installing *)

2 (CarlsonRF @@ (Total[(Apply[Times, Sqrt[{a, b, c, d}[[#]]]] & /@
                       {#, Complement[Range[4], #]}) & /@ Subsets[Range[3], {2}], {2}]^2))
   2 CarlsonRF[(Sqrt[b] Sqrt[c] + Sqrt[a] Sqrt[d])^2,
               (Sqrt[a] Sqrt[c] + Sqrt[b] Sqrt[d])^2,
               (Sqrt[a] Sqrt[b] + Sqrt[c] Sqrt[d])^2]

and the result can be seen to have permutation symmetry in a,b,c,d.

Compare:

With[{a = 2, b = 3, c = 4, d = 5},
     {N[2 CarlsonRF[(Sqrt[b] Sqrt[c] + Sqrt[a] Sqrt[d])^2,
                    (Sqrt[a] Sqrt[c] + Sqrt[b] Sqrt[d])^2,
                    (Sqrt[a] Sqrt[b] + Sqrt[c] Sqrt[d])^2], 25],
      NIntegrate[1/Sqrt[(a - t) (b - t) (c - t) (d - t)], {t, -∞, 0}, 
                 Method -> "DoubleExponential", WorkingPrecision -> 25]}]
   {0.2963150890686989232562657, 0.2963150890686989232562657}
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.