Specifying number of clusters and members in CommunityGraphPlot

Question

The Issue

I am trying to specify the number of clusters and the number of members in each cluster that the CommunityGraphPlot function forms as part of a larger project.

The Code

This code generates a complete graph with a random edge weight between 0 and 1 assigned between each node. It then outputs a community graph plot, choosing communities based on some algorithm.

n = 10;
q = n * (n - 1)/2;
g = CompleteGraph[n, EdgeWeight -> RandomReal[{0, 1}, {q}]];
FindGraphCommunities[g];
CommunityGraphPlot[g, 
 Method -> "Hierarchical",(*EdgeLabels\[Rule]"EdgeWeight",*) 
 ImageSize -> Full]

The Question

This function is something of a black box, and while reviewing the documentation, I was unable to find any options to specify how many clusters it forms, or how many members are in each cluster. Are there workarounds to this issue?

Also I would appreciate if anyone could point me towards any literature on the methods used to choose clusters, or any other functions that could be used to specify the number of clusters, etc.

Thank you.

Answer 1

CommunityGraphPlot[g] 

will find community based on

FindGraphCommunities[g]

So that

CommunityGraphPlot[g]

is the same as

CommunityGraphPlot[g, FindGraphCommunities[g]]

You could put labels like the following to show # of members:

n = 10;
q = n*(n - 1)/2;
g = CompleteGraph[n, EdgeWeight -> RandomReal[{0, 1}, {q}]];
com = FindGraphCommunities[g];
member = Length /@ com;
CommunityGraphPlot[g, com, Method -> "Hierarchical", 
 CommunityLabels -> member, ImageSize -> Full, 
 PlotLabel -> "# cluster: " <> ToString[Length[com]]]

For controlling size of cluster, FindGraphPartition can be useful. For example, find the partition of 3 clusters with {5, 3, 2} members.

n = 10;
q = n*(n - 1)/2;
g = CompleteGraph[n, EdgeWeight -> RandomReal[{0, 1}, {q}]];
comm = FindGraphPartition[g, {5, 3, 2}] 

{{2, 4, 5, 8, 9}, {1, 6, 7}, {3, 10}}

and use this set to visualize the result with CommunityGraphPlot:

CommunityGraphPlot[g, comm]