Find the area enclosed by a loop in an image (Contour in a plot)

Question

Is there a way to simply compute the area enclosed by a line in an image, like this:

Here's an example of what I mean by a few of the "enclosed regions"

Solution 1

These sorts of images are produced on my end by a ListContourPlot of some functions, so in principle I have a mesh of domain points and associated function values. However, importantly, this doesn't give me exactly the points show in these contours, which are found by ListContourPlot. In principle, I suppose I could construct some method for manually finding all these points and using Green's Theorem to construct a numerical approximation of the areas. This would be a ton of work.

Solution 2

I feel like there should surely be an easier way to find these areas in post-processing/image processing. The lines are all a single, known, hue, as is the background between. I don't know where to start on this method, but hopefully you can help!

Answer 1

Here's a quick attempt using morphological image analysis on my own contour plot, since you did not provide yours:

1. Generate a contour plot with some closed contours and style it more or less like yours:

   contour = ContourPlot[
     Sin[2 x]^2 - Cos[2 y]^2, {x, y} ∈ Polygon[CirclePoints[{1, 90 Degree}, 6]],
     PlotPoints -> 75, Contours -> 4,
     ContourShading -> None, ContourStyle -> Directive[Thick, Darker@Blue],
     BoundaryStyle -> {Thick, Black},
     PlotRangePadding -> Scaled[.05]
   ]
   

2. Calculate the morphological components of the image (I pre-emptively remove the frame of the graph to avoid confusion):

   components = WatershedComponents[Show[contour, Frame -> False]]
   Colorize[components]
   

3. Measure the area of the identified components:

   ComponentMeasurements[components, "Area"]
   
   (* Out: {1 -> 91741.8, 2 -> 17916.5, 3 -> 11013.3, 4 -> 7016.} *)
   

---

In case you don't have CirclePoints in your version, replace it in the code above with:

{
  {0, 1}, {-(Sqrt[3]/2), 1/2}, 
  {-(Sqrt[3]/2), -(1/2)}, {0, -1}, 
  {Sqrt[3]/2, -(1/2)}, {Sqrt[3]/2, 1/2}
}