Can I plot the solution to an ODE without using dsolve?

Question

I have the following ODE

$\qquad x'= -x^3+\sin(t)$

I want to find numerically the initial condition $x(0)$ corresponding to the $2\pi$ periodic solution.

I tried to use DSolve, but it did not work. It gives me

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information".

I actually tried different ODEs and was able to solve them. Is there any way for me to plot the solution without solving the ODE first?

Answer 1

To answer the question in the title, yes it is definitely possible to plot the solution without solving the differential equation, by using StreamPlot.

Borrowing from MichaelE2's solution here, you can use Manipulate to find the solution graphically for a given initial condition

Manipulate[
 Show[
  StreamPlot[{1, -x^3 + Sin[t]}, {t, -4 π, 4 π}, {x, -2, 2}, 
   StreamPoints -> Fine],
  StreamPlot[{1, -x^3 + Sin[t]}, {t, -4 π, 4 π}, {x, -2, 2}, 
   StreamPoints -> {p0}, StreamStyle -> Directive[Thick, Red]]]
 , {{p0, {0, 0}}, {-4 π, -2}, {4 π, 2}, Locator}]

Answer 2

If you are satisfied with a numerical approach, this is one of the problems where ParametricNDSolve[] is called for:

pf = ParametricNDSolveValue[{x'[t] == Sin[t] - x[t]^3, x[0] == a}, x, {t, 0, 2 π}, a,
                            Method -> "StiffnessSwitching", WorkingPrecision -> 25];

(* bracket obtained from a preliminary plot of pf[a][2 π] *)
aopt = a /. FindRoot[pf[a][2 π] - a, {a, -1, 1}, WorkingPrecision -> 25]
   -0.7156846197712976536871740

xs = NDSolveValue[{x'[t] == Sin[t] - x[t]^3, x[0] == aopt}, x, {t, -2 π, 4 π}];

Plot[xs[t], {t, -2 π, 4 π}]

xs[π Range[-2, 4]]
   {-0.7156821841853735, 0.7156848515290952, -0.7156846197712976,
    0.7156846139367274, -0.7156846712483197, 0.7156846219921508,
    -0.7156846049890743}

Answer 3

As a first step I you can find numerical solutions.

Let us first repeat: the ODE is

eq = x'[t] == -x[t]^3 + Sin[t];

Mathematica does not find an analytic solution

DSolve[eq, x[t], t]

During evaluation of In[13]:= Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

(* Out[13]= DSolve[Derivative[1][x][t] == Sin[t] - x[t]^3, x[t], t] *)

So now the numerical solution with which Mathematica has no difficulty:

Let's take 5 periods

tmax = 5 (2 \[Pi]);

The inital vaule can be chosen freely.

y0 = 0; (* other examples to try: 1,-1,5,-5 *)

The solution

sol = NDSolve[eq && x[0] == y0, x[t], {t, 0, tmax}];

xx[t_] = x[t] /. sol[[1]];

Plot of the soluton, together with a pure sine for comparison

Plot[{Sin[2 \[Pi] t], xx[2 \[Pi] t]}, {t, 0, tmax/(2 \[Pi])}, 
 PlotLabel -> 
  "Numerical solution of an ODE\nblue curve -> solution\nyellow curve -> pure \
sine"]

EDIT

It seems that the solution has the general form

f[t] = d[t] + p[t]

where d[t] is a function decaying with time and p[t] is a "universal" function with period 2 Pi. The initial conditions show up only in d[t].