Using Collect to group derivatives together

Question

Is there a way to combine derivatives that are a result from the product rule back together using Collect.

For example, I'd like to collect

x Dt[y,b] + y Dt[x,b]

back to

Dt[x y,b]

I can do this with a rule:

Rule = {x Dt[y,b] + y Dt[x,b] -> Dt[xy,b]};
x Dt[y,b] + y Dt[x,b]/.Rule

But this forces me to use a new variable: xy instead of the actual product of x and y. Moreover, I have many different rules to follow so typing all those out would be taxing. Has anyone else tried doing this and succeeded?

Answer 1

Dt, by its nature, will apply the derivative rules until it can't. You could make it Inactive.

rule = {x Dt[y, b] + y Dt[x, b] -> Inactive[Dt][x y, b]};
x Dt[y, b] + y Dt[x, b] /. rule
(*  Inactive[Dt][x y, b]  *)

---

Some generic transformations:

With[{dt = Inactive[Dt]},
 byparts = # /. Plus[f_ dt[g_, v_], rest___] :> Simplify[dt[f g, v] + rest - g dt[f, v]] &;
 sum = # /. Plus[dt[f_, v_], dt[g_, v_], rest___] :> dt[f + g, v] + rest &;
 ];
pauseDt = Inactivate[#, Dt] &;

Example

Simplify[
 Dt[x, b] + y Dt[x, b] + x Dt[y, b] // pauseDt,
 TransformationFunctions -> {byparts, sum, Automatic}]
(*  Inactive[Dt][x (1 + y), b]  *)

Check:

Expand@Activate[%]
(*  Dt[x, b] + y Dt[x, b] + x Dt[y, b]  *)