How to find variable values that make an expression divergent or undefined?

Question

How can I find all the values of a variable at which a given expression diverges or becomes undefined?

Example:

expr=1/(1-x^2);

Desired result:

(* {1,-1} or {{x->1},{x->-1}} *)

Example:

expr=x/x

Desired result:

(* 0  or {0}  or {{x->0}} *) 

EDIT: Some users pointed out I can just find when the Denominator[expr]==0, but that doesn't work for some functions like:

expr=Exp[1/x]

Answer 1

Update 1

The following function works for all the cases mentioned so far except for the trivial x/x case.

 findPoles[expr_] := Module[{pos, npos},
 (*find position of all Power in the fullform of the function*)
 pos = Position[FullForm[expr], Power];
 (*drop the last 0 to get the position of the actual power
 expression*)
 npos = Drop[pos[[#]], -1] & /@ Range[Length[pos]];
 (*extract those position, 
 find their denominators and delete those which have none. 
 Lastly Solve for the poles*)
 Solve[DeleteCases[Denominator[Extract[FullForm[expr], npos]], 1] == 
    0, x]]

Testing the function

 expr[1] = 1/(1 - x^2);
 expr[2] = Exp[1/x];
 Table[findPoles[expr[i]], {i, 2}]
 (*{{{x -> -1}, {x -> 1}}, {{x -> 0}}}*)

---

Using the Denominator command and then Solve

findDiv[exp_] := 
Which[exp === 1, {{x -> 0}}, True, Solve[Denominator[exp] == 0, x]]

expr = 1/(1 - x^2);
findDiv[expr]
(*{{x\[Rule]-1},{x\[Rule]1}}*)

expr = x/x;
findDiv[expr]
(*{{x\[Rule]0}}*)

Answer 2

expr = 1/(1 - x^2);

FunctionDomain[expr, x]

Plot[expr, {x, -2, 2}]

Show "complement" graphically

NumberLinePlot[
 expr == 10^6,
 {x, -2, 2},
 AspectRatio -> 1/3,
 Frame -> True,
 FrameTicks -> {Automatic, None, None, None},
 GridLines -> {Automatic, None},
 GridLinesStyle -> Directive[Gray],
 PlotStyle -> PointSize[Large],
 PlotTheme -> "Detailed"]