Inserting an indexed string into the 1st position of each pair in a list of pairs

Question

How do I insert "Z" and then a number going from 1 to end (without space) in a list?

I have the following list:

Input:

list = {{1, 1}, {2, 1}, {3, 1}, {5, 1}, {1, 2}, {2, 2}, {3, 2}}

Output:

{Z1, 1, 1}, {Z2, 2, 1},{Z3, 3, 1}...

I have tried using the commando Insert and looking at inserting at several positions, but without luck.

Answer 1

Using MapIndexed[]:

list = {{1, 1}, {2, 1}, {3, 1}, {5, 1}, {1, 2}, {2, 2}, {3, 2}};
MapIndexed[Prepend[#1, StringJoin["Z", ToString[First[#2]]]] &, list]
   {{"Z1", 1, 1}, {"Z2", 2, 1}, {"Z3", 3, 1}, {"Z4", 5, 1}, {"Z5", 1, 2},
    {"Z6", 2, 2}, {"Z7", 3, 2}}

Answer 2

Flatten /@ Transpose[{"Z" <> ToString @ # & /@ Range@Length@list, list}]

{{"Z1", 1, 1}, {"Z2", 2, 1}, {"Z3", 3, 1}, {"Z4", 5, 1}, {"Z5", 1, 2}, {"Z6", 2, 2}, {"Z7", 3, 2}}

Or

MapThread[Prepend, {list, "Z" <> ToString @ # & /@ Range@Length@list}]

Or

Join @@@ Transpose@{Array[{"Z" <> ToString @ #} &, {Length@list}], list}

Or

i = 1;
list /. {a__?NumberQ} :> {"Z" <> ToString[i++], a}

Or with Insert

Insert[list[[#]], "Z" <> ToString @ #, 1] & /@ Range@Length@list

Answer 3

I think this is a problem where Table provides a straight-forward solution.

list = {{1, 1}, {2, 1}, {3, 1}, {5, 1}, {1, 2}, {2, 2}, {3, 2}};
Table[{"Z" <> ToString[i], Sequence @@ list[[i]]}, {i, Length[list]}]

{{"Z1", 1, 1}, {"Z2", 2, 1}, {"Z3", 3, 1}, {"Z4", 5, 1}, {"Z5", 1, 2}, {"Z6", 2, 2}, {"Z7", 3, 2}}

Since list is a simple list of pairs, one might even consider

Table[{"Z" <> ToString[i], list[[i, 1]], list[[i, 2]]}, {i, Length[list]}]