OutputResponse in V9 vs V10

Question

Bug introduced in 10.0.1 and persisting through 10.2 or later

---

I have same code that works in version 9.0.1, but not in version 10.0.1.0 (according to @Sektor, it works in 10.0.0.0, too).

in = UnitStep[t - 20] - UnitStep[t - 75];
tMax = 100;
time = {t, 0, tMax};

thisWc = TransferFunctionModel[{{{0.9 (1 + 19 s)}}, 19 s}, s]

Wp23 = TransferFunctionModel[{{{E^((-2) s)}}, (1 + 2 s)^5}, s]

out = OutputResponse[
  SystemsModelFeedbackConnect[
   SystemsModelSeriesConnect[thisWc, Wp23]], in, time]

One can approximate the TF in v10 with (thanks to @Nasser):

Wp23Approx = SystemsModelDelayApproximate[Wp23]

outApprox = 
 OutputResponse[
  SystemsModelFeedbackConnect[
   SystemsModelSeriesConnect[thisWc, Wp23Approx]], in, time]

Then the Error changes from

NestList::intnm: Non-negative machine-sized integer expected at position 3 in NestList[#1/. Control`RecastDEquationsDump`xx$_[t+Optional[Pattern[<<2>>]]]:>Control`RecastDEquationsDump`xx$[t+Control`RecastDEquationsDump`nn0$+1]&,Control`RecastDEquationsDump`y$615011[t]->Control`RecastDEquationsDump`stVar$6154[t]+Control`RecastDEquationsDump`cst$6156 Subscript[\[FormalU], 1][t],2.]. >> ....

to

NDSolve::ndsz: At t == 20.00000000000057`, step size is effectively zero; singularity or stiff system suspected. >>

Surprisingly in v9 (and 10.0.0.0) both ways give the same result:

Edit: I'm using Win7 64bit

Answer 1

You can get output if you first approximate your system. You have a delayed control system there due to the E^(-2) in the numerator of the wp23 transfer function. So use this below. In addition, asking for Minimal state model allows you to solve for this specific input you have

ClearAll[t, s];
in = 2 UnitStep[t - 20] - UnitStep[t - 500];
tMax = 100;
time = {t, 0, tMax};
wp23 = TransferFunctionModel[{{{E^((-2) s)}}, (1 + 2 s)^5}, s];
wp23 = SystemsModelDelayApproximate[wp23];
thisWcA = TransferFunctionModel[{{{0.8908858730832925 (1 + 19.096 s)}}, 19.096 s}, s];
tf = SystemsModelSeriesConnect[thisWcA, wp23];
tf = SystemsModelFeedbackConnect[tf];
ss = MinimalStateSpaceModel@StateSpaceModel@tf;
out = First@OutputResponse[ss, in, time];
Plot[out /. t -> i, {i, 0, tMax}, PlotRange -> All]

See DelayControlSystems.html for more information on delay control systems and SystemsModelDelayApproximate