BUG: Problems generating FEM ElementMesh in 1-D

Question

fixed in 10.1 (windows)

---

I'm trying to build an ElementMesh for a simple 1-D problem.

First, I build the boundary ElementMesh:

Needs["NDSolve`FEM`"]
bmesh = ToBoundaryMesh[
  "Coordinates" -> {{0}, {5}, {10}},
  "BoundaryElements" -> {PointElement[List /@ #, #] &@Range@3}
  ]
bmesh["Wireframe"["MeshElementMarkerStyle" -> Blue]]

and this apparently works as expected:

Then I try to build the full ElementMesh:

mesh = ToElementMesh[bmesh,
  "RegionMarker" -> {{{2.5}, 1, 0.1}, {{7.5}, 2, 0.2}}
  ]

and this doesn't works:

If I don't add markers in the first step:

bmesh = ToBoundaryMesh[
  "Coordinates" -> {{0}, {5}, {10}},
  "BoundaryElements" -> {PointElement[List /@ Range@3]}
  ]
mesh = ToElementMesh[bmesh,
  "RegionMarker" -> {{{2.5}, 1}, {{7.5}, 2}}
  ]

the full ElementMesh is built:

but the region markers are not assigned:

Show[
 bmesh["Wireframe"],
 mesh["Wireframe"["MeshElementMarkerStyle" -> Blue]],
 mesh["Wireframe"["MeshElement" -> "BoundaryElements", 
   "MeshElementMarkerStyle" -> Red]]
 ]

I also tried using "BoundaryMarkerFunction" option but I was unsuccessfull.

Answer 1

That's an bug in the 1D case. A somewhat cumbersome way to work around that is to generate the mesh and then generate the mesh a second time where markers are computed and inserted into the mesh elements:

Needs["NDSolve`FEM`"]
bmesh = ToBoundaryMesh["Coordinates" -> {{0}, {5}, {10}}, 
   "BoundaryElements" -> {PointElement[List /@ Range@3]}];
mesh = ToElementMesh[bmesh];

mkMarker[c_, inci_] := Module[{pt1 = #[[1, 1]], pt2 = #[[2, 1]]},
    Which[
     pt2 <= 5, 1,
     pt1 >= 5, 2,
     True, 4 ]] & /@ (c[[#]] & /@ inci)

mkLineEle[c_, le_LineElement] := 
 LineElement[ElementIncidents[le], mkMarker[c, ElementIncidents[le]]]

coords = mesh["Coordinates"];
m2 = ToElementMesh["Coordinates" -> coords, 
   "MeshElements" -> (mkLineEle[coords, #] & /@ mesh["MeshElements"]),
   "BoundaryElements" -> {PointElement[
      Flatten[Position[coords, #]] & /@ bmesh["Coordinates"], {7, 5, 8}]}
   ];

Show[
 m2["Wireframe"["MeshElementMarkerStyle" -> Blue]], 
 m2["Wireframe"["MeshElement" -> "BoundaryElements", 
   "MeshElementMarkerStyle" -> Red]]]

Hope this helps.

Answer 2

This has been fixed in 10.1 (windows)

---

code

Needs["NDSolve`FEM`"]
bmesh = ToBoundaryMesh["Coordinates" -> {{0}, {5}, {10}}, 
"BoundaryElements" -> {PointElement[List /@ #, #] &@Range@3}]
bmesh["Wireframe"["MeshElementMarkerStyle" -> Blue]]

mesh = ToElementMesh[bmesh, 
  "RegionMarker" -> {{{2.5}, 1, 0.1}, {{7.5}, 2, 0.2}}]
Show[bmesh["Wireframe"], 
mesh["Wireframe"["MeshElementMarkerStyle" -> Blue]], 
mesh["Wireframe"["MeshElement" -> "BoundaryElements", "MeshElementMarkerStyle" -> Red]]]