Display a labeled multigraph

Question

Introduced in version 9, fixed in version 10.

Thanks Szabolcs for providing this screenshot showing that the bug is fixed.

---

Despite the integration of graphs and networks, multigraphs are not supported in Mathematica 8+.

In Mathematica 9+, GraphPlot misbehaves for multigraphs having labelled parallel edges:

GraphPlot[{{1 -> 2, "a"}, {1 -> 2, "b"}, {2 -> 1, "c"}}]
GraphPlot[{{1 -> 2, "a"}, {1 -> 2, "b"}, {2 -> 1, "c"}}, DirectedEdges -> True]

EdgeRenderingFunction is passed the nonsense labels, so using it is out of the question.

Due to this bug, it appears there is no easy way for Mathematica 9+ to render a multigraph with labels.

Are there any workarounds, or should I look somewhere other than Mathematica?

Answer 1

Here is a manual EdgeRenderingFunction that you can start from if you supply your labels as lists.

erf = Module[{spacing = .2, 
     transform = 
      Last@FindGeometricTransform[#, {{0, 0}, {1, 0}}]}, {Text[#, 
        transform[{1/2, #2}]], 
       GeometricTransformation[
        Arrow[BSplineCurve[{{0, 0}, {1/3, #2}, {2/3, #2}, {1, 0}}, 
          SplineWeights -> {1, 10, 10, 1}]], transform]} & @@@ 
     Thread[{#3, 
       Table[spacing*a, {a, Length@#3}] - 
        spacing*(Length@#3 + 1)/2}]] &;

GraphPlot[{{1 -> 2, {"a"}}, {2 -> 3, {"b", "c", "d"}}, {3 -> 4, {"e", 
    "f"}}, {1 -> 5, {"g", "h", "i", "j"}}, {3 -> 6, {"k"}}}, 
 EdgeRenderingFunction -> erf]

To do the same with Graph instead of GraphPlot requires a bit more work because EdgeShapeFunctions for Graphs aren't given the labels. So you need to Fold across the edges of the Graph and replace the EdgeLabels with a custom EdgeShapeFunction containing the labels for each edge.

g = Graph[{Property[1 -> 2, EdgeLabels -> {"a"}], 
    Property[2 -> 3, EdgeLabels -> {"b", "c", "d"}], 
    Property[3 -> 4, EdgeLabels -> {"e", "f"}], 
    Property[1 -> 5, EdgeLabels -> {"g", "h", "i", "j"}], 
    Property[3 -> 6, EdgeLabels -> {"k"}]}];

es[labels_] := 
 Module[{spacing = .2, 
    transform = 
     Last@FindGeometricTransform[#, {{0, 0}, {1, 0}}]}, {Text[#, 
       transform[{1/2, #2}]], 
      GeometricTransformation[
       Arrow[BSplineCurve[{{0, 0}, {1/3, #2}, {2/3, #2}, {1, 0}}, 
         SplineWeights -> {1, 10, 10, 1}]], transform]} & @@@ 
    Thread[{labels, 
      Table[spacing*a, {a, Length@labels}] - 
       spacing*(Length@labels + 1)/2}]] &

g // Fold[
   RemoveProperty[{SetProperty[{#, #2}, 
       EdgeShapeFunction -> 
        es@PropertyValue[{#, #2}, EdgeLabels]], #2}, EdgeLabels] &, #,
    EdgeList@#] &

Answer 2

I cooked up a work-around for labelling multigraphs in v11.2 without resorting to GraphPlot or forcing styles. In essence, we label edges with a temporary label which identifies the edge, and after graphical rendering, substitute in unique labels.

plotMultigraph[edges_List, labels_Association] := Module[

    (* prepare indices of lists in labels *)
    {inds = <| Rule @@@ Transpose[{Keys[labels], ConstantArray[1, Length[labels]]}] |>},

    (* produce graph graphics, labeling edges with LABEL[edge] *)
    Show @ Graph[ Table[ Labeled[edge, LABEL[edge]], {edge, edges}] ] /.

        (* replace LABEL[edge] with a unique label based on edge occurence so far *)
        LABEL[edge_] :> labels[edge][[ inds[edge]++ ]]
]

This accepts a list of edges {1->2, 2->3, ...} and an association of the labels associated with each edge <| (1-2) -> {"a", "b"}, (2->3) -> ... |>.

For example

plotMultigraph[
    {1 -> 2, 1 -> 2, 2 -> 3, 3 -> 2, 2 -> 3, 1 -> 2}, 
    <|(1 -> 2) -> {"a", "b", "c"}, (2 -> 3) -> {"d", "e"}, (3 -> 2) -> {"f"}|>]

Since we're applying Replace to Graphics, it's not clear/gauranteed that the order of encountering LABEL[edge] is the same order as passed to plotMultigraph. Hence, the ordering within the sublists of labels may need changing in applications where the label order on repeated edges matters.

This trick works also for unique edge styles (replacing Labeled with Style). You can get some cool results!