Incorrect value of infinite sum

Question

Wolfram Alpha and Mathematica give an incorrect result (numerically) for the following infinite sum:

N[Sum[((-1)^n)/(n - (-1)^n), {n, 1, Infinity}]]
(* 0.700059 *)

Here's the result on Wolfram Alpha. Why the series isn't correctly evaluated?
The answer should be $\log(2)$.

Answer 1

From NSum:

You should realize that with sufficiently pathological summands, the algorithms used by NSum can give wrong answers. In most cases, you can test the answer by looking at its sensitivity to changes in the setting of options for NSum.

For instance:

NSum[((-1)^n)/(n - (-1)^n), {n, 1, Infinity}, NSumTerms -> 100000]

(* 0.693149 - 5.15666*10^-7 I *)

which is closer to Log[2] = 0.693147….

---

Aside

One can do the sum in Mathematica if the partial sum is found by summing the odd and even parts separately:

Sum[((-1)^n)/(n - (-1)^n) /. n -> 2 k, {k, 1, n0}] +
  Sum[((-1)^n)/(n - (-1)^n) /. n -> 2 k - 1, {k, 1, n0}] // FullSimplify

(* 1/2 (HarmonicNumber[-(1/2) + n0] - HarmonicNumber[n0] + Log[4]) *)

Limit[1/2 (HarmonicNumber[-(1/2) + n0] - HarmonicNumber[n0] + Log[4]), n0 -> Infinity]

(* Log[2] *)

More succinctly and quicker (along the lines of A.G.'s comment):

Sum[((-1)^n)/(n - (-1)^n), {k, 1, Infinity}, {n, 2 k - 1, 2 k}]

(* Log[2] *)

These two are mathematically equivalent, since the partial sums are sums of an even number of terms of the original series. As alluded to in a comment, it is valid because the n-th term approaches zero, which implies the difference between consecutive partial sums of the original series approaches zero. Contrast with Euler's counterexample, Sum[(-1)^n, {n, 1, Infinity}].

Answer 2

For Nsum several options for the method of summation is allowed, with Method -> Automatic by default. If to put explicitly Method -> "AlternatingSigns" it gives the result, though to get three true digits one has to take a very high PrecisionGoal:

NSum[((-1)^n)/(n - (-1)^n), {n, 1, Infinity}, 
  PrecisionGoal -> 10^4, Method -> "AlternatingSigns"]

0.6930394027669343

On the other hand setting Method -> "WynnEpsilon" gives a wrong answer almost as in the question:

NSum[((-1)^n)/(n - (-1)^n), {n, 1, Infinity}, 
  PrecisionGoal -> 10^4, Method -> "WynnEpsilon"]

0.7015171756747272

Increasing WorkingPrecision and changing other parameters doesn't seem to help. So perhaps in this case not the best method is taken automatically.