Bug introduced in 9.0 or earlier and fixed in 10.4
Sum[(-1)^m*(1/Binomial[2*m + 2, 2] + 1/Binomial[2*m + 3, 2]), {m, 0, Infinity}]
gives the right value
-2 + π
but the same sum
Sum[(-1)^Floor[n/2]/Binomial[n + 2, 2], {n, 0, Infinity}]
gives the incorrect answer
2 (-1 + Log[4])
although all corresponding partial sums are equal and the series is absolutely convergent!
Why?
I agree that this appears to be a bug. Indeed, the partial sums described by the OP in a comment are the same. For instance
Table[Sum[(-1)^ m*(1/Binomial[2*m + 2, 2] + 1/Binomial[2*m + 3, 2]), {m, 0, mm}],
{mm, 0, 20}] ==
Table[Sum[(-1)^Floor[n/2]/Binomial[n + 2, 2], {n, 0, nn}], {nn, 1, 41, 2}]
(* True *)
This is because sums of pairs of terms in the second Sum equal individual terms in the first Sum, as is evident by examining the expressions themselves as well as by adding the terms numerically.
Table[(-1)^m*(1/Binomial[2*m + 2, 2] + 1/Binomial[2*m + 3, 2]), {m, 0, 9}]
(* {4/3, -(4/15), 4/35, -(4/63), 4/99, -(4/143), 4/195, -(4/255), 4/323, -(4/399)} *)
Table[(-1)^Floor[n/2]/Binomial[n + 2, 2], {n, 0, 19}]
Total[#] & /@ Partition[%, 2]
(* {4/3, -(4/15), 4/35, -(4/63), 4/99, -(4/143), 4/195, -(4/255), 4/323, -(4/399)} *)
The sums indeed are converging to -2 + π
(-2 + π) // N
(* 1.14159 *)
Sum[(-1)^m*(1/Binomial[2*m + 2, 2] + 1/Binomial[2*m + 3, 2]), {m, 0, 1000}] // N
(* 1.14159 *)
Sum[(-1)^Floor[n/2]/Binomial[n + 2, 2], {n, 0, 2001}] // N
(* 1.14159 *)
which is distinctly different from
2 (-1 + Log[4]) // N
(* 0.772589 *)
Addendum: These computations were performed with version 10.3. The same problem occurs in version 9.0.
The answer returned by Sum for the example with Floor is certainly incorrect.
Sum attempts to evaluate this example by reducing the input to an expression without Floor. The bug occurs due to a problematic variable localization while trying to evaluate the resulting rational-exponential sum.
Sorry for the confusion caused by this problem.
Here's a related example of this bug:
Replacing Floor by Ceiling we get the sum
Sum[(-1)^Ceiling[n/2]/Binomial[n + 2, 2], {n, 0, \[Infinity]}]
(* Out[139]= 0 *)
which is returned as 0 whereas the correct value is
Sum[(-1)^Ceiling[n/2] x^n/Binomial[n + 2, 2], {n, 0, \[Infinity]}] /. x -> 1
% // N
(* Out[142]= 2 - 2 Log[2] *)
(* Out[143]= 0.613706 *)
Furthermore, the sums starting from 1 are returned unevaluated
Sum[(-1)^Floor[n/2]/Binomial[n + 2, 2], {n, 1, \[Infinity]}]
$$\sum _{n=1}^{\infty } \frac{2 (-1)^{\left\lfloor \frac{n}{2}\right\rfloor }}{(n+1) (n+2)}$$
Sum[(-1)^Ceiling[n/2]/Binomial[n + 2, 2], {n, 1, \[Infinity]}]
$$\sum _{n=1}^{\infty } \frac{2 (-1)^{\left\lceil \frac{n}{2}\right\rceil }}{(n+1) (n+2)}$$
