The command
Variables[poly]
gives me a list of all variables that appear in the expression poly, which involved sums, products, and rational powers. Sadly, it doesn't work for more complicated expressions, such as trigonometric functions. I was wondering if there is another command that can handle expressions such as $\sin(x)+\cos(y)$.
ClearAll[x, y, z, d, h, p, m, f, g, a, w];
expr = Sin[x] + Cos[y] + z^3 + Exp[d] + h + 3 h^2 + 4 h^3 +
Integrate[Exp[p], p] +
D[Sin[m]^Exp[f], m]*Series[Sin[g], {g, 0, 3}] +
2 (E^a BesselK[0, 2 Sqrt[E^a]]) C[2]/D[Gamma[w], {w, 2}];
Cases[Variables[Level[expr, -1]], x_ /; AtomQ[x] :> x]
(* {a, d, f, g, h, m, p, w, x, y, z} *)
Level[expr, {-1}], right?
$\endgroup$
{-1} and once with AtomQ. You should either just subsume/supplant my answer or go back to the original form. (You're the one who encouraged me to post an answer; I'd have been glad to simply edit yours.)
$\endgroup$
Commented
Aug 7, 2013 at 22:26
-1 and {-1} will work in your code; that's my point. With {-1} the AtomQ becomes redundant; that's why it's not in my answer.
$\endgroup$
Commented
Aug 7, 2013 at 22:29
Using Nasser's expression code as an example:
expr = Sin[x] + Cos[y] + z^3 + Exp[d] + h + 3 h^2 + 4 h^3 +
Integrate[Exp[p], p] +
D[Sin[m]^Exp[f], m]*Series[Sin[g], {g, 0, 3}] +
2 (E^a BesselK[0, 2 Sqrt[E^a]]) C[2]/D[Gamma[w], {w, 2}];
You might use:
Variables @ Level[expr, {-1}]
{a, d, f, g, h, m, p, w, x, y, z}
To extract indexed variables such as C[2] you could use:
Cases[expr, _[_Integer], {-2}]
{C[2]}
-1 rather than {-1} because I wanted to allow for indexed variables like x[1]. Do you think I should try to extend my answer to handle both in Sin[z] + x[1], that is include z and x[1] in the output list?
$\endgroup$
Commented
Aug 7, 2013 at 22:38
Variables for polynomials, and that limits what he means by variables. But indeed, that would also include things like x[1]!
$\endgroup$
Integrate[Sqrt[1 + Exp[p^2]], {p, 0, 1}], which doesn't evaluate but is a constant? Just live with it?
$\endgroup$
Commented
Aug 7, 2013 at 22:52
Clear[GetVariables]
SetAttributes[GetVariables, HoldFirst];
GetVariables[expr_, f_:Identity, excludedContexts:{__String}:{"System`"}]:=
Cases[Unevaluated[expr],
a_Symbol/;!Or[
MemberQ[excludedContexts, Context[a]],
MemberQ[Attributes[a], Locked | ReadProtected]
] :> f[a],
{0, Infinity}
]//DeleteDuplicates
It is used like
GetVariables @ {Exp[f[x]], Sin[x y^2]}
(* {x, y} *)
or, if you need to
GetVariables[{Exp[f[x]], Sin[x y^2]}, Hold]
(* {Hold[x], Hold[y]} *)
By default, it excludes the System` context, but other contexts can be specified, too.
sr = {Exp[v_] :> v, v1_^v2_ :> {v1, v2}};
variables[expr_] := FixedPoint[Replace[Variables[# /. sr], _[x_] :> x, {1}] &, expr]
variables[Sin[Subscript[x, 1]] + Cos[Subscript[x, 2]]]
(* {Subscript[x, 1], Subscript[x, 2]} *)
variables[Sin[x] + Cos[y] + z^3 + Exp[d] + h + 3 h^2 + 4 h^3 +
Integrate[Exp[p], p] + D[Sin[m]^Exp[f], m]]
(* {d, f, h, m, p, x, y, z} *)
Perhaps what you are looking for is as simple as
vars[expr_] := DeleteDuplicates@Cases[expr, _Symbol, \[Infinity]]
vars[1 + y^2 + Sin[x] + Cos[x]]
{y, x}
Probably there are expressions on which this will fail, but it might handle those you are interested in.
